Question

I need binary combinators of the type

(a -> Bool) -> (a -> Bool) -> a -> Bool

or maybe

[a -> Bool] -> a -> Bool

(though this would just be the foldr1 of the first, and I usually only need to combine two boolean functions.)

Are these built-in?

---

If not, the implementation is simple:

both f g x = f x && g x
either f g x = f x || g x

or perhaps

allF fs x = foldr (\ f b -> b && f x) True fs
anyF fs x = foldr (\ f b -> b || f x) False fs

Hoogle turns up nothing, but sometimes its search doesn’t generalise properly. Any idea if these are built-in? Can they be built from pieces of an existing library?

If these aren’t built-in, you might suggest new names, because these names are pretty bad. In fact that’s the main reason I hope that they are built-in.

Answer 1

Control.Monad defines an instance Monad ((->) r), so

ghci> :m Control.Monad
ghci> :t liftM2 (&&)
liftM2 (&&) :: (Monad m) => m Bool -> m Bool -> m Bool
ghci> liftM2 (&&) (5 <) (< 10) 8
True

You could do the same with Control.Applicative.liftA2.

---

Not to seriously suggest it, but…

ghci> :t (. flip ($)) . flip all
(. flip ($)) . flip all :: [a -> Bool] -> a -> Bool
ghci> :t (. flip ($)) . flip any
(. flip ($)) . flip any :: [a -> Bool] -> a -> Bool