Question

I need help with an XSLT problem. I haven’t had much time to search but for what I did I couldn’t find an answer. I have xml with five fields: Policy_Type, Policy_Date, State, Zip, and amount Paid. I need to find a way to add the Amount Paid fields together for all entries that have the same Policy_Type, Policy_Date, State, and Zip. Does anyone have a suggestion on best practice for going about this in XSL?

Also these fields are being pulled from an Interbase database. If there is a way of doing this through SQL statements that would welcome as well. I’m not as comfortable with Interbase though.

Answer 1

This transformation:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:key name="kTrans" match="transaction"
  use="concat(Policy_Type,
            '+',
              Policy_Date,
            '+',
              State,
            '+',
              Zip)"/>

 <xsl:template match=
  "transaction
    [generate-id()
    =
     generate-id(key('kTrans',
                      concat(Policy_Type,
                            '+',
                              Policy_Date,
                            '+',
                              State,
                            '+',
                              Zip)
                     )[1]
                  )
    ]
  ">
  <transaction>
   <xsl:copy-of select="*[not(self::AmountPaid)]"/>

   <TotalAmountPaid>
     <xsl:value-of select=
     "sum(key('kTrans',
              concat(Policy_Type,
                   '+',
                     Policy_Date,
                   '+',
                     State,
                   '+',
                     Zip)
                     )
                     /AmountPaid
          )
     "/>
   </TotalAmountPaid>
  </transaction>
 </xsl:template>
 <xsl:template match="text()"/>
</xsl:stylesheet>

when applied on the following XML document (as no source XML document is provided!):

<transactions>
 <transaction>
  <Policy_Type>A</Policy_Type>
  <Policy_Date>2012-01-11</Policy_Date>
  <State>WA</State>
  <Zip>98004</Zip>
  <AmountPaid>189.32</AmountPaid>
 </transaction>
 <transaction>
  <Policy_Type>B</Policy_Type>
  <Policy_Date>2012-01-11</Policy_Date>
  <State>NY</State>
  <Zip>111111</Zip>
  <AmountPaid>111.11</AmountPaid>
 </transaction>
 <transaction>
  <Policy_Type>A</Policy_Type>
  <Policy_Date>2012-01-11</Policy_Date>
  <State>WA</State>
  <Zip>98004</Zip>
  <AmountPaid>223.05</AmountPaid>
 </transaction>
 <transaction>
  <Policy_Type>B</Policy_Type>
  <Policy_Date>2012-01-11</Policy_Date>
  <State>NY</State>
  <Zip>111111</Zip>
  <AmountPaid>111.11</AmountPaid>
 </transaction>
 <transaction>
  <Policy_Type>C</Policy_Type>
  <Policy_Date>2012-01-11</Policy_Date>
  <State>NY</State>
  <Zip>111111</Zip>
  <AmountPaid>111.11</AmountPaid>
 </transaction>
</transactions>

produces the wanted, correct result:

<transaction>
   <Policy_Type>A</Policy_Type>
   <Policy_Date>2012-01-11</Policy_Date>
   <State>WA</State>
   <Zip>98004</Zip>
   <TotalAmountPaid>412.37</TotalAmountPaid>
</transaction>
<transaction>
   <Policy_Type>B</Policy_Type>
   <Policy_Date>2012-01-11</Policy_Date>
   <State>NY</State>
   <Zip>111111</Zip>
   <TotalAmountPaid>222.22</TotalAmountPaid>
</transaction>
<transaction>
   <Policy_Type>C</Policy_Type>
   <Policy_Date>2012-01-11</Policy_Date>
   <State>NY</State>
   <Zip>111111</Zip>
   <TotalAmountPaid>111.11</TotalAmountPaid>
</transaction>

Explanation: Muenchian grouping.