Question

I need move the data stored in a array of bytes to a set of records located in a TList, but i’m getting this error

E2197 Constant object cannot be passed as var parameter

This code reproduce the issue.

uses
  System.Generics.Collections,
  System.SysUtils;

type
  TData = record
    Age : Byte;
    Id  : Integer;
  end;

//this code is only to show the issue, for simplicity i'm filling only the first  
//element of the TList but the real code needs fill N elements from a very big array.  
var
  List : TList<TData>;
  P : array [0..1023] of byte;
begin
  try
    List:=TList<TData>.Create;
    try
      List.Count:=1;
      //here i want to move the content of the P variable to the element 0
      Move(P[0],List[0], SizeOf(TData));

    finally
      List.Free;
    end;

  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

How i can copy the contents of a buffer to a TList Element

Answer 1

In XE2, the internal storage for TList<T> is opaque and hidden. You cannot gain access to it by normal means. All access to elements of the list are copied – references to the underlying storage are not available. So you cannot blit to it using Move. If you want a structure that you can blit to, you should consider a dynamic array, TArray<T>.

You can always use the trick of implementing a class helper for TList<TData> that would expose the private variable FItems. That’s pretty hacky but will do what you ask.

type
  __TListTData = TList<TData>;
  //defeat E2086 Type 'TList<T>' is not yet completely defined

type
  TListTDataHelper = class helper for TList<TData>
    procedure Blit(const Source; Count: Integer);
  end;

procedure TListTDataHelper.Blit(const Source; Count: Integer);
begin
  System.Move(Source, Pointer(FItems)^, Count*SizeOf(Self[0]));
end;

I guess you might want to put some parameter checking in TListTDataHelper.Blit, but I’ll leave that to you.

If you were using XE3, you could access the private storage of TList<T> by using the List property.

Move(P, Pointer(List.List)^, N*SizeOf(List[0]));

If you don’t need to blit and can use a for loop then do it like this:

type
  PData = ^TData;
var
  i: Integer;
  Ptr: PData;
....
List.Count := N;
Ptr := PData(@P);
for i := 0 to List.Count-1 do
begin
  List[i] := Ptr^;
  inc(Ptr);
end;

But I interpret your question that you wish to avoid this option.