Question

I need to copy rows in PowerPoint 2003 (just to re-use their formatting). Tried to do:

Dim oPPTRow As PowerPoint.Row

Set oPPTRow = oPPTFile.Slides(SlideNum).Shapes(1).Table.Rows(2)
oPPTFile.Slides(SlideNum).Shapes(1).Table.Rows.Add (-1)
oPPTFile.Slides(SlideNum).Shapes(1).Table.Rows(oPPTTable.Rows.Count) = oPPTRow

But it doesn’t work. Is there any other way to achieve the same?

Answer 1

The Rows.Add method lets you insert a new row before any row you like. The newly inserted row will pick up the formatting of the row you inserted it ahead of. Try this (be sure to select a tabel shape first):

Sub AddNewRow()
    Dim oTbl As Table
    Dim oSh As Shape

    Set oSh = ActiveWindow.Selection.ShapeRange(1)
    Set oTbl = oSh.Table

    With oTbl
        .Rows.Add (2)
    End With
End Sub

Passing -1 as the parameter to .Add forces PPT to add the row at the end of the table; the new cells will all be formatted the same as the cells above them (that is, the cells in the row that was previously the bottom row).

If you need to pick up formatting from some other row, I think you may need to do something like:

Sub AddNewRow()
    Dim oTbl As Table
    Dim oSh As Shape
    Dim x As Long
    Dim lNewRow As Long

    Set oSh = ActiveWindow.Selection.ShapeRange(1)
    Set oTbl = oSh.Table

    With oTbl
        .Rows.Add (-1)
        lNewRow = .Rows.Count
        ' format the new row to match the cells in row two
        With .Rows(lNewRow)
            ' step across the row cell by cell
            For x = 1 To oTbl.Columns.Count

                ' pick up row two formatting
                oTbl.Cell(2, x).Shape.PickUp
                ' apply it to new row's cell x
                .Cells(x).Shape.Apply

                ' do the same for cell's text formatting
                oTbl.Cell(2, x).Shape.TextFrame.TextRange.Font.Name = oTbl.Cell(2, x).Shape.TextFrame.TextRange.Font.Name
                ' Use above pattern to pick up/apply font bold, ital, size, color etc as needed
            Next
        End With
    End With
End Sub