Question

I need to extract multiple substrings at fixed positions from a line and the same time replace whitespaces at another position.

For example, I have a string ‘01234567890 ‘. I want to extract characters at positions 1,2,6,7,8 and the same time if position 12, 13 are whitespaces, I want to replace them with 0101. It is all position based.

What is the best way to achieve this using perl ?

I can use substr and string comparison and then concatenate them together, but the code looked rather chuncky….

Answer 1

I would probably split (or: explode) the string into an array of single chars:

my @chars = split //, $string; # // is special with split

Now we can do array slices: extracting multiple arguments at once.

use List::MoreUtils qw(all);

if (all {/\s/} @chars[12, 13]) {
   @chars[12, 13] = (0, 1);
   my @extracted_chars = @chars[1, 2, 6..8];
   # do something with extracted data.
}

We can then turn the @chars back into a string like

$string = join "", @chars;

If you want to remove certain chars instead of extracting them, you would have to use slices inside a loop, an ugly undertaking.

Complete sub with nice interface to do this kind of thing

sub extract (%) {
   my ($at, $ws, $ref) = @{{@_}}{qw(at if_whitespace from)};
   $ws //= [];
   my @chars = split //, $$ref;
   if (all {/\s/} @chars[@$ws]) {
      @chars[@$ws] = (0, 1) x int(@$ws / 2 + 1);
      $$ref = join "", @chars;
      return @chars[@$at];
   }
   return +();
}

my $string = "0123456789ab \tef";
my @extracted = extract from => \$string, at => [1,2,6..8], if_whitespace => [12, 13];

say "@extracted";
say $string;

Output:

1 2 6 7 8
0123456789ab01ef