Question

I need to get the list of dates between two dates – for e.g. I have start date 03302012 and enddate 05302012 and I need the output like

03302012
03312012
04012012
04022012
...
05282012
05292012
05302012

• Feel free to use your date format – I will make transformation by myself.
  Thank you very much!

Answer 1

You could do this by using a recursive template. It’s not the greatest solution since this is subject to stack overflow or out of memory errors (if the date interval you give it is large enough), but it can be a place to start.

First thing you need for the example below is a way to check a generated value and make sure it’s a valid date (you can find some examples online for that; I just used a sample from an open source project and imported the file in the example just to keep it shorter).

Then, the idea is to generate the dates by adding a day to the previous one, and then a day to the current one on so on. If the day overflows, you add one to the month and start again from day 1. If month overflows you do the same with the year and start from month 1. Theoretically the only one that never overflows is the year (but you will limit that with the end value of the interval).

You generate a date and you validate it. If it’s valid and haven’t reached the end of the interval you try to generate another by adding days to it (that’s what happens in block X).

When you get an invalid value, then something overflowed. It can only be the day or the month (as I mentioned above). I first check for the month (block Y). If that’s the case I start from day 1 of month 1 but for the next year. If it’s the day that overflowed (block Z), then I start from day 1 of the next month.

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:import href="http://www.getsymphony.com/download/xslt-utilities/source-code/54294/"/>
  <xsl:output method="xml" omit-xml-declaration="yes" encoding="UTF-8" indent="yes" />

  <xsl:variable name="startDate" select="'03302012'" />  <!-- MMddyyyy format -->
  <xsl:variable name="endDate" select="'05302012'" /> <!-- MMddyyyy format -->

  <xsl:template match="/">
    <values>
      <xsl:call-template name="GenerateList">
        <xsl:with-param name="day" select="number(substring($startDate, 3, 2))" />
        <xsl:with-param name="month" select="number(substring($startDate, 1, 2))" />
        <xsl:with-param name="year" select="number(substring($startDate, 5))" />
      </xsl:call-template>
    </values>
  </xsl:template>

  <xsl:template name="GenerateList">
    <xsl:param name="day" select="1" />
    <xsl:param name="month" select="1" />
    <xsl:param name="year" select="1" />

    <!-- 1 = valid, 0 = invalid according to the imported file -->
    <xsl:variable name="validationResult">
      <xsl:call-template name="date-is-valid">
        <xsl:with-param name="day" select="$day"/>
        <xsl:with-param name="month" select="$month"/>
        <xsl:with-param name="year" select="$year"/>
      </xsl:call-template>
    </xsl:variable>

    <xsl:choose>
      <xsl:when test="$validationResult = 0">

        <xsl:choose>
          <xsl:when test="$month &gt; 12">
            <!-- block Y -->
            <xsl:call-template name="GenerateList">
              <xsl:with-param name="day" select="1" />
              <xsl:with-param name="month" select="1" />
              <xsl:with-param name="year" select="$year + 1" />
            </xsl:call-template>
          </xsl:when>
          <xsl:otherwise>
            <!-- block Z --> 
            <xsl:call-template name="GenerateList">
              <xsl:with-param name="day" select="1" />
              <xsl:with-param name="month" select="$month + 1" />
              <xsl:with-param name="year" select="$year" />
            </xsl:call-template>
          </xsl:otherwise>
        </xsl:choose>

      </xsl:when>
      <xsl:otherwise>
        <!-- block X -->
        <!-- same MMddyyyy format as the interval values -->
        <xsl:variable name="currentDate" select="concat(format-number($month, '00'), format-number($day, '00'), $year)" />
        <value>
          <xsl:value-of select="$currentDate" />
        </value>
        <xsl:if test="not($currentDate = $endDate)">
          <xsl:call-template name="GenerateList">
            <xsl:with-param name="day" select="$day + 1" />
            <xsl:with-param name="month" select="$month" />
            <xsl:with-param name="year" select="$year" />
          </xsl:call-template>
        </xsl:if>

      </xsl:otherwise>
    </xsl:choose>

  </xsl:template>
</xsl:stylesheet>