Question

I need to increment a column (Counts) +1 for every NEW DocNumber. So if the DocNumber is the same for three columns, the counter will be 1,2,3 etc. Below is the code. I got it to the point where it will update the entire table, just not based on the same or different docnumbers. Can someone help me with the logic here?

Basically, I want to restart the counter when it hits a new TempDocNumber

DECLARE @DocTable Table (DetailID FLOAT, TempDocNumber FLOAT, Counts INT)
INSERT INTO @DocTable (DetailID, TempDocNumber, Counts)
SELECT DetailID, DocumentNumber, 0 FROM ChargebackDetailTempTable


declare @Counter int
Set @Counter = 0
Update @Doctable
SET @Counter = counts = @Counter + 1

-- start counter over when new tempdocnumber

Answer 1

You could just create your insert like this:

DECLARE @DocTable Table (DetailID FLOAT, TempDocNumber FLOAT, Counts INT)
INSERT INTO @DocTable (DetailID, TempDocNumber, Counts)
SELECT  DetailID, 
        DocumentNumber TempDocNumber, 
        ROW_NUMBER() OVER(PARTITION BY DocumentNumber ORDER BY DetailId) Counts
FROM ChargebackDetailTempTable

No UPDATE needed.

For SQL Server 2000

Assuming that DetailID is an identity column, you can try the following (again, no UPDATE needed):

DECLARE @DocTable Table (DetailID FLOAT, TempDocNumber FLOAT, Counts INT)
INSERT INTO @DocTable (DetailID, TempDocNumber, Counts)
SELECT  DetailID, 
        TempDocNumber,
        Counts = (  SELECT COUNT(T1.DetailID) + 1
                    FROM ChargebackDetailTempTable T1
                    WHERE T1.DetailID < T.DetailID and T1.TempDocNumber = T.TempDocNumber)
FROM ChargebackDetailTempTable T