Question

i need to remove xmi node if there is only 1 child. If i remove xmi node i need to copy attributes to new root node.

<xmi:XMI attribute="2" xmlns:xmi="http://www.omg.org/spec/XMI/20110701" xmlns:a="A">
<namespace:node attribute2="att">
...
</namespace:node>
</xmi:XMI>

i need to get

<namespace:node attribute2="att" attribute="2" xmlns:xmi="http://www.omg.org/spec/XMI/20110701" xmlns:a="A">
...
</namespace:node>

but if there is

<xmi:XMI attribute="2" xmlns:xmi="http://www.omg.org/spec/XMI/20110701" xmlns:a="A">
<namespace:node attribute2="att">
...
</namespace:node>
<otherNode/>
</xmi:XMI>

no changes must be done.

Any help appreciated.

Answer 1

This XSLT 1.0 transformation:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xmi="http://www.omg.org/spec/XMI/20110701">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="xmi:XMI[not(*[2])]">
  <xsl:apply-templates/>
 </xsl:template>

 <xsl:template match="xmi:XMI[not(*[2])]/*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@* | ../@*"/>
     </xsl:copy>
 </xsl:template>
</xsl:stylesheet>

when applied on the following XML document :

<xmi:XMI attribute="2"
           xmlns:xmi="http://www.omg.org/spec/XMI/20110701"
           xmlns:a="A" >
        <namespace:node attribute2="att" xmlns:namespace="some:namespace">
          ...
        </namespace:node>
        <otherNode/>
</xmi:XMI>

produces the wanted, correct result (no changes):

<xmi:XMI xmlns:xmi="http://www.omg.org/spec/XMI/20110701" xmlns:a="A" attribute="2">
   <namespace:node xmlns:namespace="some:namespace" attribute2="att">
          ...
        </namespace:node>
   <otherNode/>
</xmi:XMI>

When applied on this XML document:

<xmi:XMI attribute="2"
           xmlns:xmi="http://www.omg.org/spec/XMI/20110701"
           xmlns:a="A" >
        <namespace:node attribute2="att" xmlns:namespace="some:namespace">
          ...
        </namespace:node>
</xmi:XMI>

again the wanted, correct result is produced (the xmi:XMI element is “deleted” and its attributes are copied to its only child):

<namespace:node xmlns:namespace="some:namespace"    
 xmlns:xmi="http://www.omg.org/spec/XMI/20110701" xmlns:a="A" 
 attribute="2" attribute2="att">
          ...
</namespace:node>