Question

I need to send requests that are formatted exactly as I specify, including whitespace. What’s the best way to achieve this?

Example of the kind of request I want to send:

GET
/
key=val
Host:example.com

The protocol is a simple request-response protocol like HTTP. I’d prefer to take advantage of LWP’s existing code where possible.

Answer 1

I think it is be achievable with LWP. It’s a bit of work, to be honest.

I’ve take a look at it, and you need to actually implement your own protocol (see LWP::Protocol) because that’s where the actual request is created. Afterwards, you will need to enable that protocol as implementor of http (or https):

LWP::Protocol::implementor('http', 'MyFunkyProtocol');

For an example, take a look at LWP::Protocol::GHTTP code.

Simply saying, you need to create a package implementing a request method. In that method, you need to assemble the request, open the connection, send it and receive the response.

---

Here’s a simple working example.

MyFunkyProto.pm:

package MyFunkyProto;

use LWP::Protocol;
@ISA = qw/LWP::Protocol/;

use HTTP::Response;
use IO::Socket;
use Carp qw/croak/;

sub request
{
    my ($self, $request, $proxy, $arg, $size, $timeout) = @_;

    my $remote = IO::Socket::INET->new(
        Proto     => "tcp",
        PeerAddr  => "example.com",
        PeerPort  => "http(80)"
    ) or croak('unable to connect');

    my $message = <<EOF;
GET
/
key=val
Host:example.com
EOF

    $remote->print($message);
    $remote->flush();

    local $/;
    my $resp = HTTP::Response->parse(<$remote>);

    $remote->close();

    return $resp;
};

1;

script.pl:

#!/usr/bin/env perl

use strict;
use warnings;
use lib '.';

use MyFunkyProto;
use LWP::Protocol;
use LWP::UserAgent;

LWP::Protocol::implementor('http', 'MyFunkyProto');

my $fr = HTTP::Request->new('GET', 'http://www.example.com/');
my $ua = LWP::UserAgent->new();

my $r = $ua->request($fr);
print $r->as_string();

Note that you will actually want to construct the request (and obtain the host and port) from the $request object. Or if you’re lazy, just store it somewhere in that object.