Question

I need to transform a div-based XHTML layout into a table based layout using XSLT 1.0. For the basic transformation, I have a stylesheet (below) that creates the table structure just fine.

I cannot figure out how to parse multiple class attributes on the input XHTML to add table-specific attributes to the output. (Yes, I would like these as new table attributes, even though classes are copied across)

My sample XHTML is:

<div class="table align-center">
    <div class="tr">
        <div class="td"><p>Table Cell 1</p></div>
        <div class="td"><p>Table Cell 2</p></div>
    </div>
</div>

A basic XSL that builds the table structure OK, is as follows:

<xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="div[contains(@class, 'table')]">
    <table>
        <xsl:copy-of select="attribute::node()"/>
        <xsl:apply-templates/>
    </table>
</xsl:template>

<xsl:template match="div[contains(@class, 'tr')]">
    <tr>
        <xsl:copy-of select="attribute::node()"/>
        <xsl:apply-templates/>
    </tr>
</xsl:template>

<xsl:template match="div[contains(@class, 'td')]">
    <td>
        <xsl:copy-of select="attribute::node()"/>
        <xsl:apply-templates/>
    </td>
</xsl:template>

This stylesheet produces:

<table class="table align-center">
    <tr class="tr">
        <td class="td"><p>Table Cell 1</p></td>
        <td class="td"><p>Table Cell 2</p></td>
    </tr>
</table>

What I would like to produce is this:

<table class="table align-center" align="center">
    <tr class="tr">
        <td class="td"><p>Table Cell 1</p></td>
        <td class="td"><p>Table Cell 2</p></td>
    </tr>
</table>

Is it possible to do this with XSLT 1.0? I’d like the solution to be general enough to add 2 or more classes and parse them to add the required table attributes.

Thank you!

Answer 1

This XSLT 1.0 style-sheet…

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html" indent="yes"/>
<xsl:strip-space elements="*" />

<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

  <xsl:template match="div[starts-with(@class, 'table ')]">
    <table>
        <xsl:call-template name="extract-class">
          <xsl:with-param name="class-list" select="normalize-space( substring-after(@class,'table '))" />
        </xsl:call-template>
        <xsl:apply-templates select="@*|node()"/>
    </table>
</xsl:template>

<xsl:template match="div[starts-with(@class, 'tr ')]">
    <tr>
        <xsl:apply-templates select="@*|node()"/>
    </tr>
</xsl:template>

<xsl:template match="div[starts-with(@class, 'td ')]">
    <td>
        <xsl:apply-templates select="@*|node()"/>
    </td>
</xsl:template>

<xsl:template name="extract-class">
  <xsl:param name="class-list" />
  <xsl:if test="contains($class-list,'-')">
    <xsl:variable name="name-value" select="substring-before(concat($class-list,' '),' ')" />
    <xsl:attribute name="{substring-before($name-value,'-')}">
      <xsl:value-of select="substring-after($name-value,'-')" />
    </xsl:attribute>
    <xsl:call-template name="extract-class">
      <xsl:with-param name="class-list" select="normalize-space(substring-after($class-list,' '))" />
    </xsl:call-template> 
  </xsl:if>  
</xsl:template>

</xsl:stylesheet>

…when applied to this document…

<div class="table align-center border-1 cellspacing-5">
    <div class="tr">
        <div class="td"><p>Table Cell 1</p></div>
        <div class="td"><p>Table Cell 2</p></div>
    </div>
</div>

…yields…*

<table align="center" border="1" cellspacing="5" class="table align-center border-1 cellspacing-5">
  <tr class="tr">
    <td class="td">
      <p>Table Cell 1</p>
    </td>
    <td class="td">
      <p>Table Cell 2</p>
    </td>
  </tr>
</table>