Question

I need to write a method doing a formatting of numeric value given a pattern as one of the parameter, in actionscript.

For example:

a. 12345.00 using format pattern ###,###.## resulting 12,345.00
b. 12345.00 using format pattern ##,##,##.## resulting 1,23,45.00

Initially, I thought that NumberFormatter able to do that, but after reading documentation, it seems you are not able to accept pattern.

Any idea how to implement this ? I’m using Flex 4.1

UPDATE: I made an advanced formatter based on the sample created by Jason. You can download it here : link

Answer 1

UPDATE:
After a bit more thought on this custom formatter class, I’ve decided to update it a bit. You can see the updated CustomPatternFormatter class here.

The updated class adds:

• The ability to pass any string, not just numeric values.
• A flag to ensure the length of the input string matches the length of the format pattern.

I hope this helps!

Original answer:

You’ll have to create custom Formatter to handle this. Here’s something I threw together real fast. You may have to adjust it to fit your situation.

CustomNumericFormatter.as

package 
{
    // formatters/myFormatter/SimpleFormatter.as
    import mx.formatters.Formatter;
    import mx.formatters.SwitchSymbolFormatter;

        public class CustomNumericFormatter extends Formatter 
        {
            private static const VALID_PATTERN_CHARS:String = "#,.";

            // Declare the variable to hold the pattern string.
            public var formatString:String = "";

            // Constructor
            public function CustomNumericFormatter() {
                // Call base class constructor.
                super();
            }

            // Override format().
            override public function format(value:Object):String {
                if (error)
                    error = null;

                // If value is null, or empty String just return "" 
                // but treat it as an error for consistency.
                // Users will ignore it anyway.
                if (!value || (value is String && value == ""))   
                {
                    error = "0 Length String";
                    return "";
                }

                // -- value --              
                // 1. Validate value - must be a nonzero length string.
                if (!value || String(value).length == 0 || isNaN(Number(value)))
                {
                    error = "Invalid object type passed to formatter";
                    return "";
                }

                // 2. If the value is valid, format the string.
                var fStrLen:int = 0;
                var letter:String;
                var n:int;
                var i:int;
                var v:int;

                // Make sure the formatString is valid.
                n = formatString.length;
                for (i = 0; i < n; i++)
                {
                    letter = formatString.charAt(i);
                    if (letter == "#")
                    {
                        fStrLen++;
                    }
                    else if (VALID_PATTERN_CHARS.indexOf(letter) == -1)
                    {
                        error = "You can only use the following symbols in the formatString: # , .";
                        return "";
                    }
                }

                var returnString:String = "";
                var vStr:String = String(value).replace(".", "").split("").reverse().join("");
                var fStr:Array = formatString.split("").reverse();
                var fChar:String;

                for (v = 0; v < vStr.length; v++)
                {   
                    if (fStr.length > 0)
                    {
                        do 
                        {
                            fChar = fStr.shift();

                            if (fChar != "#")
                                returnString += fChar;

                        } while (fChar != "#" && fStr.length > 0);
                    }


                    returnString += vStr.charAt(v);
                }   

                return returnString.split("").reverse().join("");
            }
        }
}