Question

I noticed in the code base I have to read that sometimes property definition includes an empty (). What’s the meaning of that? And it has nothing to do with arrays.

For example :

Public Property TotalPages() As Integer

Answer 1

I know it seems strange (well to us C#’ers) but properties can have parameters in VB.NET.

So you can have

Public Class Student
    Private ReadOnly _scores(9) As Integer

    ' An indexed Score property
    Public Property Score(ByVal index As Integer) As _
        Integer
        Get
            Return _scores(index)
        End Get
        Set(ByVal value As Integer)
            _scores(index) = value
        End Set
    End Property

    Private _score As Integer

    ' A straightforward property
    Public Property Score() As _
        Integer
        Get
            Return _score
        End Get
        Set(ByVal value As Integer)
            _score = value
        End Set
    End Property

End Class

Public Class Test
    Public Sub Test()

        Dim s As New Student

        ' use an indexed property
        s.Score(1) = 1

        ' using a standard property   
        ' these two lines are equivalent
        s.Score() = 1
        s.Score = 1

    End Sub
End Class

So your declaration of

Public Property TotalPages() As Integer

Is a straightforward non-indexed property, e.g. with no parameters.