Question

I receive 2 XML files from a third party service every day and I need to combine them using VBS as it is the only available technology on the server that consumes the XML. Each of the XML files has the same structure –

<section>
    <lot>
        <number>8</number>
        <identifier>au23-zx78a</identifier>
    </lot>
    <lot>
        <number>23</number>
        <identifier>au23-zx78a</identifier>
    </lot>
    ...and so on...
</section>

I need to take all of the lot nodes (including any and all children) from file 1 and insert them into file 2 before saving file 2 to be consumed by another service. Using VBS.

I have searched the web and I have found ways to get a node out using VBS but I am lost on getting the nodes into another file. I have written and scrapped 3 or 4 scripts today because I have not been able to get it right.

I know that the logic is this –

load file 1,
load file 2,
get the lot nodes from file 1,
loop through the lot nodes from file 1 and append them as children of the section node in file 2,
save file 2

Can anyone help me by pointing me in the right direction?

Answer 1

Here’s a simple way of doing it: load both xml files into MSXML2.DomDocument objects, select all the lot nodes from the first document, clone them and insert them into the second document.

option explicit

' collect xml file paths from the command line
dim xmlpath1: xmlpath1 = WScript.Arguments(0)
dim xmlpath2: xmlpath2 = WScript.Arguments(1)

' open up the xml files, this might need some error handling
dim xmldoc1: set xmldoc1 = CreateObject("MSXML2.DomDocument")
xmldoc1.async = false
xmldoc1.load xmlpath1
xmldoc1.setProperty "SelectionLanguage", "XPath"
dim xmldoc2: set xmldoc2 = CreateObject("MSXML2.DomDocument")
xmldoc2.async = false
xmldoc2.load xmlpath2

' get a collection of lot nodes
dim lots: set lots = xmldoc1.selectNodes("/section/lot")
' loop through each lot, clone it and add it to the second document
dim lot
for each lot in lots
    dim l: set l = lot.cloneNode(true)
    xmldoc2.documentElement.appendChild l
next

' overwrite the second document
xmldoc2.save xmldoc2.url

The script (if called merge-xml.vbs) would be run from the command line

cscript merge-xml.vbs xml1.xml xml2.xml