Question

i run a tcl send expect script in a file and execute as ./file

#!/usr/bin/expect
spawn -noecho telnet 42.0.1.11
set timeout 900
expect "login:"
send "admin\r"
expect "Password: "
send "ram\r"
expect "#"
for {set i 0} {$i <= 1000000000} {incr i} {
 some router commands
}

this works fine until router reloads, when router reloads, this script stops as spawn id not open., i want to resume the script (i dont know exactly how much time it takes to reload as it varies most of time).,is there any way to resume the script automatically

Thanks

Answer 1

Wrap your login procedure into a proc and call it again if you get EOF. Here is the basic idea, just remember that there may be other ways for things to go wrong.

Edit: I have rewritten the code after some investigation. This has been tested on Linux with “router reboot” being simulated by Solaris 10 workstation (sorry no Cisco to reboot here). As I mentioned ping implementations differ from OS to OS so proc Ping may need to be changed to accommodate your situation.

#!/usr/bin/tclsh

package require Expect

proc RouterLogin {ip user pass} {
    spawn -noecho telnet $ip
    set timeout 60
    expect "login:"
    send "$user\r"
    expect "Password: "
    send "$pass\r"
    expect "#"
    return $spawn_id
}

proc RouterPing ip {
    # ping retry limit      - 3
    # delay between retries - 30 seconds
    set limit   3
    set delay   30
    set attempt 1
    set result false
    while {$result == false && $attempt <= $limit} {
        set result [Ping $ip]
        incr attempt
        if {!$result && $attempt <= $limit} {
            # wait $delay seconds
            after [expr {1000 * $delay}]
        }
    }
    return $result
}

proc Ping ip {
    set pingCmd "ping -c 1 $ip"
    catch {eval exec $pingCmd} pingRes
    if {[regexp "bytes from" $pingRes]} {
        return true
    } else {
        return false
    }
}

proc RouterExec {ip user pass commandList} {
    set spawn_id [RouterLogin $ip $user $pass]
    set timeout 30
    foreach cmd $commandList {
        send "$cmd\r"
        expect {
            "#" {
                # you are good
                puts "Command executed successfully"
            }
            eof {
                # wait 5 minutes
                after [expr {1000 * 60 * 5}]
                if {[RouterPing $ip]} {
                    # ping was successful, relogin and resume
                    set spawn_id [RouterLogin $ip $user $pass]
                } else {
                    # ping was not successful, abort execution
                    return false
                }
            }
            timeout {
                puts "INF: timeout"
                return false
            }
        }
    }
    send "logout\r"
    return true
}

set commandList [list command1 command2 command3]

RouterExec "42.0.1.11" "admin" "ram" $commandList