Question

I run some sas queries on a monthly basis and they export data to specific folders. Problem is I have to manually make these folders before I run the code so SAS wont error out.

Is there any way to automate this?

My folders have to be named in this fashion:

number of the Month – Name of the Month Year (12 – Dec 2011). I would also like to create a subfolder called Excel.

Also is there any way the month and number is populated automatically…so when I run this in January it changes to (1 – Jan 2012)?

Answer 1

The X or SYSTASK commands can do this.

However, if you are in the Enterprise Guide environment (I don’t believe) it is allowed by default in 9.2. I think 9.3 is going to allow it by default in the local environment (SAS DUMMY blog)

Example:

options noxwait;

data _null_;
 month=strip(put(month(today()),2.));
 year=strip(put(year(today()),4.));
 monname=put(today(),monname3.);
 dir_name=month !! " - " !! monname !! " " !! year;
 call symputx('dir_name',dir_name);
run;
%put &dir_name;

x "cd D:\Data";
x "%str(mkdir %"&dir_name%")";

Another option is the DCREATE function

Example:

data _null_;
 month=month(today());
 year=year(today());

 dir_name=put(month,2.) !! " - " !! put(today(),monname3.) !! " " !! put(year,4.);
 NewDirectory=dcreate(dir_name,'D:\Data\');
run;