Question

I searched from internet, but I only found php solutions to this problem. Please help if you know how to do this in perl.

I am trying to generate a webpage showing the content of a directory on my server’s local disk. For example, a page containing the following will do the work

<file name="file1" href="file1" />
<dir name="dir1" href="dir1/" />
<dir name="dir2" href="dir2/" />

Thank you for your help.

Answer 1

Modifications have to be made to secure the script and also in jailing it. However, the idea can be implemented like:

#!/usr/bin/perl -T

use strict;
use warnings;

use CGI;
use File::Basename;
use File::Spec;
use Path::Trim;

my $cgi = CGI->new();

if ( my $file = $cgi->param('file') ) {
    open my $fh, '<', $file or die $!;

    print $cgi->header(
        '-type'           => 'application/octet-stream',
        '-attachment'     => basename($file),
        '-Content_Length' => -s $file,
    );

    binmode $fh;
    print while <$fh>;
}
else {
    my $path = $cgi->param('path');                                                                

    print $cgi->header(), $cgi->start_html();                                                                                               

    # remove redundant current directory and parent directory entries                                                                       
    my $pt = Path::Trim->new();                                                                                                             
    $pt->set_directory_separator('/');                                                                                                      
    $path = $pt->trim_path($path);                                                                                                          

  # remove all ../ and ./ that have accumulated at the beginning of the path and                                                            
  # make the path absolute by prepending a /                                                                                                
    $path =~ s{^ (\.\.? /)+ }{}x;                                                                                                           
    $path = "/$path" unless $path =~ m{^ / }x;                                                                                              

    print $cgi->h1($path);                                                                                                                  

    opendir my $dh, $path or die $!;                                                                                                        
    my @entries = grep { $_ !~ /^ \. $/x } readdir $dh;
    closedir $dh;

    print $cgi->start_ul();
    for my $entry ( sort { $a cmp $b } @entries ) {
        if ( -d File::Spec->catfile( $path, $entry ) ) {
            my $abs_entry = File::Spec->catfile( $path, $entry );
            my $anchor = $cgi->a( { 'href' => "?path=$abs_entry" }, $entry );
            print $cgi->li($anchor);
        }
        else {
            my $abs_entry = File::Spec->catfile( $path, $entry );
            my $anchor = $cgi->a( { 'href' => "?file=$abs_entry" }, $entry );
            print $cgi->li($anchor);
        }
    }
    print $cgi->end_ul(), $cgi->end_html();
}