Question

I tried to add lighting to my OpenGLES2 application following the tutorial at http://www.learnopengles.com/android-lesson-two-ambient-and-diffuse-lighting/

Unlike in above tutorial,I have FPS camera movements.In the vertex shader I have hard coded camera position (u_LightPos) in world coodinates.But its giving weird lighting effects when I move the camera.Do I have to transform this position using projection/view matrix ?

uniform mat4 u_MVPMatrix;         
uniform mat4 u_MVMatrix;       


attribute vec4 a_Position;    
attribute vec4 a_Color;     
attribute vec3 a_Normal;    

varying vec4 v_Color;  

void main()         
{                         
 vec3 u_LightPos=vec3(0,0,-20.0);
 vec3 modelViewVertex = vec3(u_MVMatrix * a_Position); 
 vec3 modelViewNormal = vec3(u_MVMatrix * vec4(a_Normal, 0.0));     

 float distance = length(u_LightPos - modelViewVertex);           

  // Get a lighting direction vector from the light to the vertex.
  vec3 lightVector = normalize(u_LightPos - modelViewVertex);   

   // Calculate the dot product of the light vector and vertex normal. If the normal and light vector are
   // pointing in the same direction then it will get max illumination.
  float diffuse = max(dot(modelViewNormal, lightVector), 0.1);    

   // Attenuate the light based on distance.
   diffuse = diffuse * (1.0 / (1.0 + (0.25 * distance * distance))); 

   // Multiply the color by the illumination level. It will be interpolated across the triangle.
  v_Color = a_Color * diffuse;   

   // gl_Position is a special variable used to store the final position.
   // Multiply the vertex by the matrix to get the final point in normalized screen coordinates.
 gl_Position = u_MVPMatrix * a_Position;                         
}  

Answer 1

When performing arithmetic on vectors, they must be in the same coordinate space. You’re subtracting modelViewVertex (view space) from u_LightPos (world space), which will give you a bogus result.

You need to decide if you want to do lighting calculations in world space, or view space (either should be valid), but you must transform all of the inputs to the same space.

That means either getting the vertex/normal/lightpos in world space, or the vertex/normal/lightpos in view space.

Try multiplying your lightpos by the view matrix (not modelview), and then using that in your computation instead of u_Lightpos, I think it should work.