Question

I tried to select a specific value from database by using this code:

    Dim rs, data, lo

    data = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & _
    Server.MapPath("games.mdb")

    rs = Server.CreateObject("ADODB.Recordset")

    rs.open("select * FROM [index] where ID1=1 ", data)

    Image1.ImageUrl = "images/" + rs("url").ToString

    lo =rs("url")

    rs.MoveNext()
    rs.Close()

When I run it, I get:

show 

System.__ComObject 

Answer 1

The problem is that you are trying to use COM objects when in fact you should be using native System.Data.OleDb classes.

Based on the example that Microsoft provides, here is a rewrite of your code using native classes:

    Dim connectionString As String

    connectionString = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("games.mdb")

    Using connection As New System.Data.OleDb.OleDbConnection(connectionString)
        Using command As New System.Data.OleDb.OleDbCommand("select * FROM [index] where ID1=1")
            ' Set the Connection to the new OleDbConnection.
            command.Connection = connection

            ' Open the connection and execute the select command. 
            Try
                connection.Open()
                Dim oReader As System.Data.OleDb.OleDbDataReader

                oReader = command.ExecuteReader()
                If oReader.Read() Then
                    Image1.ImageUrl = "images/" + oReader("url").ToString
                End If
            Catch ex As Exception
                Console.WriteLine(ex.Message)
            End Try
        End Using
        ' The connection is automatically closed when the code exits the Using block. 
    End Using