Question

I try to learn Haskell before my exam session and it’s still magic for me. Today I tried to write a program, which reads a file, and writes it’s lines in reversed order to another file. Result? Lots of errors. Here is my code:

import IO

readLines :: Handle -> [String] -> [String]
readLines handler list = do
    eof <- hIsEOF handler
    if eof then list
        else do
            line <- hGetLine handler
            readLines handler (list ++ [line])

writeLines :: Handle -> [String] -> [String]
writeLines handler list = if length list == 0 then list
    else do
        line <- head list
        hPutStrLn handler line
        writeLines tail list

fileToList :: FilePath -> [String]
fileToList filename = do
    handler <- openFile filename ReadMode
    list <- (readLines handler [])
    hClose handler
    list

invLines :: FilePath -> FilePath -> IO ()
invLines input output = do
    handler <- openFile output WriteMode
    inverted <- reverse (fileToList input)
    writeLines handler inverted
    hClose handler

main = invLines "in.txt" "out.txt"

I will be grateful if you can explain me my mistakes.

Answer 1

Ok first of,

IO ==> System.IO

next let’s look at readLines (PS readFile would work nicely here)

readLines :: Handle -> [String] -> [String] --You have to return an IO [String] here.
    readLines handler list = do
    eof <- hIsEOF handler
    if eof then return list --Return an IO list
        else do
            line <- hGetLine handler
            readLines handler (list ++ [line])

Next onto writeLines (PS writeFile would also help)

writeLines :: Handle -> [String] -> [String] -- You have to return IO of something, I'd recommend ().
writeLines handler list = if length list == 0
    then list --Change to return ()
    else do
        line <- head list --Should be let here. Like let line = head list
        hPutStrLn handler line
        writeLines tail list -- Should be writeLines handler $ tail list instead.

Next is fileToList

fileToList :: FilePath -> [String] --Has to be IO [String]
fileToList filename = do
    handler <- openFile filename ReadMode
    list <- (readLines handler [])
    hClose handler
    list -- Have to use return list

Oh and you seem to invert the lines twice, so you actually end up with a very large copying routine, removing the reverse in there and you get the correct result.

The Code at The End

import System.IO

readLines :: Handle -> [String] -> IO [String]
readLines handler list = do
    eof <- hIsEOF handler
    if eof 
    then return list
    else do
      line <- hGetLine handler
      readLines handler (line:list)

writeLines :: Handle -> [String] -> IO ()
writeLines handler list = if length list == 0 then return ()
    else do
        let line = head list
        hPutStrLn handler line
        writeLines handler $ tail list

fileToList :: FilePath -> IO [String]
fileToList filename = do
    handler <- openFile filename ReadMode
    list <- (readLines handler [])
    hClose handler
    return list

invLines :: FilePath -> FilePath -> IO ()
invLines input output = do
    handler <- openFile output WriteMode
    inputLines <- fileToList input
    writeLines handler inputLines
    hClose handler

main = invLines "in.txt" "out.txt"

And rewritten using more of the library:

invLines input output = do
    inputLines <- readFile input
    writeFile output . unlines . reverse . lines $ inputLines

invLines2 input output = 
    readFile input >>= writeFile output . unlines . reverse . lines

Big lesson to learn You can’t return normal functions from inside an IO do block. You must return an IO something