Question

I trying to write a function which gets an integer number , represented by string , and check if all his chars are digits and return #t \ #f accordingly . Thats the code –

(define (splitString str) (list->vector (string->list str)))

(define myVector 0)
(define flag #t)

(define (checkIfStringLegal str) (
(set! myVector (splitString str))
(do (  (i 0 (+ i 1))  )  ; init
  ((= i (vector-length myVector)) flag) ; stop condition
  (cond ((>= 48 (char->integer (vector-ref myVector i)) ) (set! flag #f))
        ((<= 57 (char->integer (vector-ref myVector i)) )(set! flag #f))


  )    
)
) 
) 

Few explanations –

(list->vector (string->list str)) – convert string the char list .

(vector-ref myVector i) – char from the myVector at place i .

Its run OK , but when I try to use this func , like (checkIfStringLegal "444") I get –

application: not a procedure;
 expected a procedure that can be applied to arguments
  given: #<void>
  arguments...:
   #t

Answer 1

Try this:

(define (checkIfStringLegal str)
  (andmap char-numeric?
          (string->list str)))

This is how the procedure works:

1. It transforms the string into a list of characters, using string->list
2. It validates each character in the list to see if it’s a number, applying the predicate char-numeric? to each one
3. If all the validations returned #t, andmap will return #t. If a single validation failed, andmap will return #f immediately

That’s a functional-programming solution (and after all, this question is tagged as such), notice that your intended approach looks more like a solution in a C-like programming language – using vectors, explicit looping constructs (do), mutation operations (set!), global mutable definitions … that’s fine and it might eventually work after some tweaking, but it’s not the idiomatic way to do things in Scheme, and it’s not even remotely a functional-programming solution.

EDIT:

Oh heck, I give up. If you want to write the solution your way, this will work – you had a parenthesis problem, and please take good notice of the proper way to indent and close parenthesis in Scheme, it will make your code more readable for you and for others:

(define (splitString str) (list->vector (string->list str)))
(define myVector 0)
(define flag #t)

(define (checkIfStringLegal str)
  (set! myVector (splitString str))
  (do ((i 0 (+ i 1)))
    ((= i (vector-length myVector)) flag)
    (cond ((>= 48 (char->integer (vector-ref myVector i)))
           (set! flag #f))
          ((<= 57 (char->integer (vector-ref myVector i)))
           (set! flag #f)))))

Even so, the code could be further improved, I’ll leave that as an exercise for the reader:

• Both conditions can be collapsed into a single condition, using an or
• The exit condition should be: end the loop when the end of the vector is reached or the flag is false