Question

I use (Mac)Vim in my projects set to use 2 spaces for tabs and even have a script which converts all tabs to 2 spaces on save.

When I work with other developers though, sometimes they use tabs instead of spaces and I am looking for a quick way to switch two different vim configurations, would love to switch them on the command line, like this

macvim --oh-no-not-tabs-again .

What’s the best practice on this?

Answer 1

You can have autocommands fired on a per-directory basis, so you can configure anything you want automatically without hotkeys. Here’s what I came up with:

" set up global defaults, these are mine
set tabstop=4
set softtabstop=4
set shiftwidth=4
set smarttab
set expandtab
set autoindent
set smartindent

" override tab settings on a per-directory basis
function! SetStandardTabs()
  set noexpandtab
  set tabstop=8
  set softtabstop=4
endfunction

augroup PerDirectoryTabs
  autocmd!
  autocmd BufRead,BufEnter,BufNewFile /path/to/csharp/files/* call SetStandardTabs()
augroup END

This configures vim to automatically figure out when you’re in a subtree of /path/to/csharp/files and sets the buffer-local variables the way you want. Put it in your .vimrc and you’re good to go.

Edit Here’s some code to put in your .vimrc that searches up the tree for the nearest “local” .vimrc and sources (loads) it. Use with caution! Don’t set globals or do anything “interesting”, you’ll get hard-to-diagnose behaviors. I have not exhaustively tested it. It might eat your children. You have been warned!

" per-subtree .vimrc
function! FindAndSourceLocalVimrc()
  if exists('g:inFindLocalVimrc')
    return
  endif
  let g:inFindLocalVimrc=1

  let v = findfile('.vimrc', '.;')
  if exists('v')
    let v = fnamemodify(v, ':p')
    if v != $MYVIMRC
      exe "source " . v
    endif
  endif

  unlet g:inFindLocalVimrc
endfunction

call FindAndSourceLocalVimrc()

I’m sure 10 years from now I’ll find some already-existing built-in way to do it in one line.