Question

I use media player classic to play videos.
I can make a batch file to play a playlist, like this:

mpc.exe video1.avi video2.avi video3.avi ...

It works.

Now I would like to make a batch file that plays all videos in a folder sorted randomly.

Any idea?

Thanks

Answer 1

The code below assumes you are playing files from the current directory, and it assumes none of your .avi file names begin with =. It wouldn’t take much to eliminate those limitations.

If you have too many files in your folder, then eventually the command length will exceed the maximum allowed length of 8191 bytes.

@echo off
setlocal disableDelayedExpansion
for /f "delims==" %%A in ('set file. 2^>nul') do set "%%A="
for /f "tokens=1* delims=:" %%A in (
  'dir /b /a-d *.avi^|findstr /n "^"'
) do (
  set "file.%%A=%%B"
  set "cnt=%%A"
)
set "cmd=mpc.exe"
for /l %%N in (%cnt% -1 1) do call :buildCmd %%N
%cmd%
exit /b

:buildCmd
set /a N=%random% %% %1
set "skip="
if %N% gtr 0 set "skip=skip=%N%"
for /f "%skip% tokens=1* delims==" %%A in ('set file.') do (
  set cmd=%cmd% "%%B"
  set "%%A="
  exit /b
)