Question

I use php DOMDocument for XSLT transforming one XML to another and i need to use additional tag – mytag in resulting document tag like

<mytag:full-text>...</mytag:full-text>

to define this tag i tryed construction like this:

<xsl:namespace-alias stylesheet-prefix="mytag" result-prefix="mytag"/>

and so i get an error

Warning: DOMDocument::load() [domdocument.load]: Namespace prefix mytag on full-text is not defined

what’s i am doing wrong?

Answer 1

Here is a complete code example how to do this:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:mytag="my:tag" exclude-result-prefixes="mytag">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="b">
  <b>
    <mytag:full-text>Some full-text here</mytag:full-text>
  </b>
 </xsl:template>
</xsl:stylesheet>

When this transformation is applied on the following XML document:

<a><b/></a>

the wanted, correct result (the new element added under b) is produced:

<a>
   <b>
      <mytag:full-text xmlns:mytag="my:tag">Some full-text here</mytag:full-text>
   </b>
</a>