Question

I want it to be working like this so then d disappears etc.

?- remove_last_item([a,b,c,d], L).    
L = [a, b, c] ?    

Does anyone know how to do this as I got this line
but what other line should I add to this so then the
above can be achieved.

Answer 1

In Prolog usually, to understand the question is to have your answer already. So you need to define a predicate, remove_last_item(A,B) such that B is A without the last item. So what is list in Prolog? Like in Lisp, it is recursively defined on top of pairs, with special symbol – empty list – signifying the “end of list”.

What does that mean? A pair, '.'(A,B), obviously has two parts. The list [a,b,c,d] is then encoded as '.'(a,'.'(b,'.'(c,'.'(d,[])))). This can also be written as [a|[b,c,d]], or [a,b|[c,d]], or [a,b,c|[d]], or [a,b,c,d|[]]. Here a is what’s known as “head” and [b,c,d] a “tail” or “rest” of the list [a,b,c,d].

So now we just write down what we want our predicate to say, from the simplest case up:

remove_last_item([_A],[]).
remove_last_item([A|B],[A|C]):- B=[_|_], remove_last_item(B,C).

It reads, “removing last item from a singleton list leaves us with an empty list; removing last item from a list of more than one element means removing the last item from the rest of the list, coming after its head”.

edit: Another way to look at it is by “starting from the top”: writing down some equivalency “law”, which the predicate must follow:

remove_last_item(L,R):- is_list(L), is_list(R), same_head(L,R),
                        tail(L,L1), tail(R,R1), 
  remove_last_item(L1,R1).

We still don’t “know” what remove_last_item “does”, we just wrote down an equivalency law that it must follow, right? But then it becomes the very definition itself that we’re after. Fleshing out all the suggestive names, it becomes the (familiar)

remove_last_item(L,R):- L=[A|L1], R=[A|R1], remove_last_item(L1,R1).

So now we can recognize this as structural recursion over lists, and just add a termination clause, to add some “substance” to it.