Question

I want to be able to write:

generate 'Cat', 'meow'

and define the generate function in such a way that it produces:

class Cat
  meow: ->
    @.__proto__.constructor.name + ' says meow.'

so that I can write:

garfield = new Cat
garfield.meow() # "Cat says meow"

Answer 1

If you don’t mind polluting your global namespace, I actually got this snippet running in the ‘try coffeescript’ runner at the CoffeeScript site:

root = exports ? window
alert = alert or console.log

gen = (clsname, val) ->
  root[clsname] = class
    meow: => "#{clsname} says #{val}"

gen 'Cat', 'meow'
g = new root.Cat
alert g.meow()

gen 'Dog', 'woff'
d = new root.Dog
alert d.meow()

Not 100% what you asked for, but it’s almost what you wanted, isn’t it?

Edit: Actually, the first script only worked in the browser, not the (Node.js-based) CLI, corrected the script.

If you know you’ll only live in the browser, you can loose root.Cat and only say Cat, but if you want Node.js and browser compat, you’ll have to live with root.*

Edit 2: It’s generally a better idea to return the class from the generating function rather than magically putting it in a namespace. It’s also possible to make the method names dynamic. With some inspiration from @Loren, the asker (notice how it doesn’t need to refer the global object anymore):

alert = alert or console.log

gen = (clsname, val) ->
  C = class
  C.prototype[val] = -> "#{clsname} says #{val}"
  C

Cat = gen 'Cat', 'meow'
console.log Cat
g = new Cat
alert g.meow()

Dog = gen 'Dog', 'woff'
d = new Dog
alert d.woff()