Question

I want to check the current date if its equal to last three days of month excluding saturdays and sundays…

I can get the last day of month

SELECT DATEADD(s,-1,DATEADD(mm, DATEDIFF(m,0,GETDATE())+1,0))

I am not sure how to check the getdate() with last three days of month excluding saturdays and sundays..

Will be of great help..
Thanks

Answer 1

-- make sure Sunday is the first day of the week:
SET DATEFIRST 7;

DECLARE 
  @today SMALLDATETIME,
  @nextmonth SMALLDATETIME;

-- today at midnight is the number of days since 1900-01-01
-- the first day of nextmonth is one month after the first 
-- day of the current month 
SELECT 
  @today = DATEDIFF(DAY, '19000101', CURRENT_TIMESTAMP),
  @nextmonth = DATEADD(MONTH, 1, @today-DAY(@today)+1);

-- so if today is greater than 3 days prior to the first of next month
-- and today is not a Saturday or a Sunday:
IF @today >= DATEADD(DAY, -3, @nextmonth) 
  AND DATEPART(WEEKDAY, @today) NOT IN (1,7)
BEGIN
  PRINT 'Bazinga!';
END

If what you really meant is that you want the last three non-weekend days in the month, then:

SET DATEFIRST 7;

DECLARE 
  @today SMALLDATETIME,
  @nextmonth SMALLDATETIME;

SELECT 
  @today = DATEDIFF(DAY, 0, GETDATE()),
  @nextmonth = DATEADD(MONTH, 1, @today-DAY(@today)+1);

;WITH x AS
(
  -- get the 5 days prior to the first day of next month:
  SELECT TOP (5) d = DATEADD(DAY, -ROW_NUMBER() OVER 
   (ORDER BY [object_id]), @nextmonth) FROM sys.all_objects
), 
y AS
(
  -- get the last three days that aren't on Sat/Sun:
  SELECT TOP (3) d FROM x 
  WHERE DATEPART(WEEKDAY, d) NOT IN (1,7)
  ORDER BY d DESC
)
-- now find out if today is in those three days:
-- (by definition, today can't be Sat/Sun)
SELECT 'Bazinga!' FROM y WHERE d = @today;

This will yield no results if today is not in those three days.