Question

I want to extract the paragraphs from a text variable that retrieved from the DB.

for extracting the pargaphs from file handler i use the below code :

local $/ = undef;
@paragarphs =<STDIN> 

what is the best option to extract paragraphs from a text variable using perl and if there are module on cpan that do this type of task ?

Answer 1

You’re almost there. Setting $/ to undef will slurp in the entire text in one go.

What you want is local $/ = ""; to enable paragraph mode, as per perldoc perlvar (emphasis my own):

$/

The input record separator, newline by default. This influences Perl’s
idea of what a “line” is. Works like awk’s RS variable, including
treating empty lines as a terminator if set to the null string (an
empty line cannot contain any spaces or tabs). You may set it to a
multi-character string to match a multi-character terminator, or to
undef to read through the end of file. Setting it to “\n\n” means
something slightly different than setting to “” , if the file contains
consecutive empty lines. Setting to “” will treat two or more
consecutive empty lines as a single empty line. Setting to “\n\n”
will blindly assume that the next input character belongs to the next
paragraph, even if it’s a newline.

---

Of course, it is possible to get a filehandle to read from a string instead of a file:

use strict;
use warnings;
use autodie;

my $text = <<TEXT;
This is a paragraph.

Here's another one that 
spans over multiple lines.

Last paragraph
TEXT

local $/ = "";
open my $fh, '<', \$text;

while ( <$fh> ) {

    print "New Paragraph: $_";
}

close $fh;

Output

New Paragraph: This is a paragraph.

New Paragraph: Here's another one that
spans over multiple lines.

New Paragraph: Last paragraph