Question

I want to get a notification when a usb device is inserted/removed/enabled/disabled.
I am registering to “__InstanceOperationEvent” for Win32_USBControllerDevice.

The problem is that although I get the insert/removed notifications for all the devices.
I get the enabled/disabled events only for USB storage devices.

What am I doing wrong?

Thanks in advance

Answer 1

It’s a little hard to grasp what you are talking about without providing a code sample or telling us what language you are working in.

The Win32_USBController class is an associator of the Win32_PnPEntity class which does have an instance of all USB devices regardless of type. So an __InstanceOperationEvent for this class DOES provide notifications for all devices, not just USB storage devices. More appropriately, it will work for any PnP-compatible USB device.

The following script is a point of concept written in VBScript. It will notify you of all USB components when a device is connected or disconnected. I tested with USB storage devices, USB mouse and keyboard, and various other devices I had lying around. All of them worked. I tested on Vista x64 but this should work with any version of Windows.

vbscript Sample:

strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")

Set colEvents = objWMIService.ExecNotificationQuery _
    ("Select * From __InstanceOperationEvent Within 1 " _
        & "Where TargetInstance Isa 'Win32_USBControllerDevice'")

While True
    Set objEvent = colEvents.NextEvent

    Select Case objEvent.Path_.Class
    Case "__InstanceCreationEvent"
        strOutput = "Device inserted:" & vbCr
    Case "__InstanceDeletionEvent"
        strOutput = "Device removed:" & vbCr
    Case Default
        strOutput = objEvent.Path_.Class & vbCr
    End Select

    strDeviceName = objEvent.TargetInstance.Dependent
    strDeviceName = Replace(strDeviceName, Chr(34), "")
    arrDevicePart = Split(strDeviceName, "=")
    strDeviceName = arrDevicePart(1)

    Set colUSBDevices = objWMIService.ExecQuery _
        ("Select * From Win32_PnPEntity Where DeviceID = '" & strDeviceName & "'")
    For Each objUSBDevice in colUSBDevices
        strOutput = strOutput & objUSBDevice.Description & vbCr
    Next

    WScript.Echo strOutput
Wend

Determining when a devices is enabled or disabled is similar but has a few distinct differences. You’ll want to use the Win32_PnPEntity class which is basically an enumeration of all installed PnP devices. You’ll want be focusing on the ConfigManagerErrorCode property for each instance. This provides contains the same information that you will find in the Device status portion of Device Manager. You can see why it would be useful to watch this propery for any given device. When a device changes to show the code (0) for normal operation, we can safely assume that a device has been enabled. When this code changes to code 22, we know that a devices has been disabled. (All other codes indicate error states.) The __InstanceModificationEvent is a good choice to watch for changes in any instances of the Win32_PnPEntity class.

If you’re interested in the possible error codes you can throw in a WScript.Echo statement near the beginning of the script where it enumerates all of the possible values.

vbscript Sample:

Const wbemFlagUseAmendedQualifiers = &H20000

strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")

Set objPnPEntityClass = objWMIService.Get("Win32_PnPEntity", wbemFlagUseAmendedQualifiers)
arrValues = objPnPEntityClass.properties_("ConfigManagerErrorCode").qualifiers_("values")
valueMap = objPnPEntityClass.properties_("ConfigManagerErrorCode").qualifiers_("valuemap")

WScript.Echo "Gathering Device Manager error codes..."
Set dictErrorCodes = CreateObject("Scripting.Dictionary")
For i = 0 to Ubound(arrValues)
    dictErrorCodes.add valueMap(i), arrValues(i)
    '  0, This device is working properly.
    ' 22, This device is disabled.
Next

Set objPnPEntityClass = Nothing

WScript.Echo "Setting up event notification..."
Set colEvents = objWMIService.ExecNotificationQuery _
    ("Select * From __InstanceModificationEvent Within 1 " _
        & "Where TargetInstance Isa 'Win32_PnPEntity'")

WScript.Echo "Waiting..."
While True
    Set objEvent = colEvents.NextEvent
    Set objDevice = objEvent.TargetInstance

    Select Case objDevice.ConfigManagerErrorCode
    Case 0      ' This device is working properly.
        strOutput = objDevice.Caption & " is working properly." & vbCr
    Case 22     ' This device is disabled.
        strOutput = objDevice.Caption & " has been disabled." & vbCr
    Case Default
        strDeviceStatus = arrValues(objDevice.ConfigManagerErrorCode)
        strOutput = "(" & objDevice.Caption & ") " &  strDeviceStatus & vbCr
    End Select

    WScript.Echo strOutput
Wend