Question

I want to include the some region plots in a Manipulate structure, however the rendering is almost prohibitively slow. The code is

ClearAll[regions, rplot]
r:regions[n_Integer, o_Integer] := r = Apply[And, 
    Subsets[Table[(#1 - Cos[t])^2 + (#2 - Sin[t])^2 <= 1, {t, 2 Pi/n, 
       2 Pi, 2 Pi/n}], {o}], {1}] &
r:rplot[n_Integer, o_Integer] := r = Show[{RegionPlot[
     Evaluate[regions[n, o][x, y]], {x, -2, 2}, {y, -2, 2},
     PlotRange -> {{-2, 2}, {-2, 2}}, PlotRangePadding -> .1, 
     Frame -> False, PlotPoints -> 100], 
    Graphics[Table[Circle[{Cos[t], Sin[t]}, 1], {t, 2 Pi/n, 2 Pi, 2 Pi/n}]]}]

Which produces graphics like

GraphicsGrid[{{rplot[3, 2], rplot[5, 3]}, {rplot[7, 2], rplot[4, 1]}}]

The above takes about 40 seconds to calculate and render on my computer.
Can anyone suggest a way to get similar quality graphics more quickly?

---

Note 1: I’ve memoized the graphics object so that doesn’t need to recalculate it each time in my demonstration – but it’s too slow even the first time.
Note 2: I’m happy with rasterized images, so maybe a flood fill type solution would be an option…
Note 3: I need something like Manipulate[
rplot[n, o], {n, 2, 10, 1, Appearance -> "Labeled"}, {{o, 1},
Range[1, (n + 1)/2], ControlType -> RadioButtonBar}] to be usable.

Answer 1

I previously posted this as an addition to my other answer. It’s inspired by Simon’s analytic approach, with some modifications to speed things up

intersect[n_, o_] :=
  With[{a = Pi/2 - (o-1) Pi/n},
   If[o-1 >= n/2, Return[{}]]; (* intersection is {} *)
   Polygon[
    Join[Table[{Sin[a] + Sin[phi], (-Cos[a] + Cos[phi])}, {phi, -a, a-2 a/10, 2 a/10}], 
     Table[{Sin[a] + Sin[phi], (Cos[a] - Cos[phi])}, {phi, a, -a+2 a/10, -2 a/10}]]]]

rplot2[n_, o_] := With[{pl = intersect[n, o], opac = .3, col = ColorData[1]},
  Graphics[{{Opacity[opac], 
     Table[{col[k], Rotate[pl, Mod[o - 1, 2] Pi/n + 2 Pi k/n, {0, 0}]}, {k, n}]},
    {Black, Circle[Through[{Re, Im}[Exp[I #]]]] & /@ (Range[n] 2 Pi/n)}}]
 ]

First of all, I’m using that for given value of n and o, the intersection region between the i-th and i+o-1-th circle is the same as the intersection region between the first and o-th circle except for a rotation over an angle 2 Pi (i-1)/n, so it suffices to calculate the region once and use Rotate to rotate the region.

Also, instead of using a ParametricPlot to plot the intersection region, I’m using a Polygon so I only need to calculate some points on the boundary which saves time.

The result for GraphicsGrid[{{rplot2[3, 2], rplot2[5, 2]}, {rplot2[7, 3], rplot2[4, 1]}}] looks like

And the timings I get are

rplot2[10, 3]; // Timing

(* ==> {0.0016, Null} *)

compared to those for Simon’s solution

rplot[10, 3]; // Timing

(* ==> {0.16519, Null} *)