Question

I want to reverse string in Assembly x-86. meaning – If I got “1234”, I want to that my result will be “4321”. I think to push each char to the stack, and the pop them. But I don’t know to implement this.I need a buffer for this? (I can override the orginal string).

Answer 1

Something like this could work (assuming 32-bit mode, written using NASM syntax):

; finding string length:
mov ebx, mystr ; current position within the string
mov ecx, 0 ; current string length

l1:
mov al, [ebx] ; fetch a character from the string
cmp al, 0 ; is this string end?
je l2 ; yes, it is

inc ebx ; increment the position from where we'll read next character
inc ecx ; increment length
jmp l1 ; repeat

l2: ; ecx = string length

; reversing the string:
cmp ecx, 2 ; is the string too short?
jb l4 ; yes, it has 0 or 1 chars, we're done

mov ebx, mystr ; ebx points to the first char in the string
lea edx, [ebx+ecx-1] ; edx = ebx+ecx-1 - points to the last char in the string
shr ecx, 1 ; ecx = half the string length

l3:
mov al, [ebx]
xchg al, [edx]
mov [ebx], al ; [ebx] and [edx] swapped
inc ebx ; advance head pointer
dec edx ; advance tail pointer
loop l3 ; decrement ecx and if ecx isn't 0, repeat

l4:
;...

; string (NULL-terminated):
mystr db '1','2','3','4',0