Question

I want to:

1. select all attributes “foo”, which are string values, and store the values in a list.
2. transform each value of attribute “foo” in this list using some map in my xslt to a number.
3. select the max value of the list and output that.

So given the following xml:

<t>
    <tag foo="A">apples</tag>
    <tag foo="C">oranges</tag>
    <tag foo="B">trees</tag>
</t>

And the following mapping:

<xsl:variable name="myMap">
    <entry key="A">1</entry>
    <entry key="B">2</entry>
    <entry key="C">3</entry>
</xsl:variable>

The output would be:

<max>3</max>

Another question, why can’t I indent my code? I’m putting spaces but it’s not working.

Answer 1

I This standard XSLT 1.0 transformation (most resembling your approach):

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:variable name="vrtfMap">
  <entry key="A" value="1"/>
  <entry key="B" value="2"/>
  <entry key="C" value="3"/>
  <entry key="X" value="8"/>
 </xsl:variable>

 <xsl:variable name="vMap" select=
  "document('')/*/xsl:variable[@name = 'vrtfMap']/*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="@foo">
  <xsl:attribute name="foo">
   <xsl:value-of select="$vMap[@key = current()]/@value"/>
  </xsl:attribute>
 </xsl:template>
</xsl:stylesheet>

when applied on the following XML document (as you didn’t provide any):

<t foo="X">
    <a foo="A">
        <b foo="B"/>
    </a>
    <c foo="C"/>
</t>

produces the wanted, correct result:

<t foo="8">
   <a foo="1">
      <b foo="2"/>
   </a>
   <c foo="3"/>
</t>

Explanation: Appropriate use of the XSLT current() function.

---

II. XSLT 1.0 solution using keys for speed

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kValFromKey" match="entry/@value" use="../@key"/>

 <xsl:variable name="vrtfMap">
  <entry key="A" value="1"/>
  <entry key="B" value="2"/>
  <entry key="C" value="3"/>
  <entry key="X" value="8"/>
 </xsl:variable>

 <xsl:variable name="vMap" select=
  "document('')/*/xsl:variable[@name = 'vrtfMap']/*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="@foo">
  <xsl:variable name="vCur" select="."/>

  <xsl:attribute name="foo">
   <xsl:for-each select="document('')">
    <xsl:value-of select="key('kValFromKey', $vCur)"/>
   </xsl:for-each>
  </xsl:attribute>
 </xsl:template>
</xsl:stylesheet>

When this transformation is applied on the same XML document (above), the same correct result is produced.

Explanation:

1. Use of <xsl:for-each select="document('')"> to set the current document to the stylesheet, so that the key() function will use the key index built for this document.

2. Saving the node matched by the template in a variable so that we can use it inside the xsl:for-each — current() cannot be correctly used here, because it gets the current node on which xsl:for-each operates.

UPDATE: The OP has now clarified in a comment that his biggest problem is finding the maximum.

<xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>
     <xsl:strip-space elements="*"/>

     <xsl:variable name="vrtfMap">
      <entry key="A" value="1"/>
      <entry key="B" value="2"/>
      <entry key="C" value="3"/>
     </xsl:variable>

     <xsl:variable name="vMap" select=
      "document('')/*/xsl:variable[@name = 'vrtfMap']/*"/>

     <xsl:template match="/">
     <xsl:variable name="vDoc" select="."/>

      <xsl:variable name="vFoosMapped"
           select="$vMap[@key = $vDoc/*/*/@foo]"/>
      <max>
       <xsl:value-of select=
         "$vFoosMapped
            [not($vFoosMapped/@value > @value)]
              /@value
         "/>
      </max>
     </xsl:template>
</xsl:stylesheet>

When given this XML document (the one provided by the OP lacks a singlr top element):

<t>
    <tag foo="A">apples</tag>
    <tag foo="C">oranges</tag>
    <tag foo="B">trees</tag>
</t>

the wanted, correct result is produced:

<max>3</max>

Remark: A more efficient way of calculating maximum (or minimum — in a similar way) in XSLT 1.0 is to do this:

<xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>
     <xsl:strip-space elements="*"/>

     <xsl:variable name="vrtfMap">
      <entry key="A" value="1"/>
      <entry key="B" value="2"/>
      <entry key="C" value="3"/>
     </xsl:variable>

     <xsl:variable name="vMap" select=
      "document('')/*/xsl:variable[@name = 'vrtfMap']/*"/>

     <xsl:template match="/">
     <xsl:variable name="vDoc" select="."/>

      <xsl:variable name="vFoosMapped"
           select="$vMap[@key = $vDoc/*/*/@foo]"/>
      <max>
       <xsl:for-each select="$vFoosMapped">
         <xsl:sort select="@value" data-type="number" order="descending"/>

         <xsl:if test="position() = 1">
          <xsl:value-of select="@value"/>
         </xsl:if>
       </xsl:for-each>
      </max>
     </xsl:template>
</xsl:stylesheet>

Another question, why can’t I indent my code? I’m putting spaces but
it’s not working.

This is a SO bug that they failed to fix for many months.

Most probably you are using IE. If your version is 9, then do the following:

1. Press F12.

2. In the window that pops up click on the right-most menu and select: “Document mode: IE9 Standards”

Now you should be able to see the code with indentation.