Question

i want to set fade effect to the GridRow when i remove it using removeChld() function

please tell me the solution …

Answer 1

You can do this:

<?xml version="1.0" encoding="utf-8"?>
<mx:Grid xmlns:mx="http://www.adobe.com/2006/mxml">
    <mx:Script>
        <![CDATA[
            import flash.display.DisplayObject;

            import mx.containers.GridRow;
            import mx.effects.Effect;
            import mx.effects.Fade;
            import mx.events.EffectEvent;

            override public function removeChild(child:DisplayObject):DisplayObject {
                if(child is GridRow) {
                    var fade:Fade = new Fade;
                    fade.alphaFrom = 1;
                    fade.alphaTo = 0;
                    fade.addEventListener(EffectEvent.EFFECT_END, fadeEndHandler);
                    fade.play([child]);
                } else {
                    super.removeChild(child);
                }

                return child;
            }

            private function fadeEndHandler(e:EffectEvent):void {
                super.removeChild(GridRow(e.effectInstance.target));
            }

        ]]>
    </mx:Script>
</mx:Grid>

Make this a new MXML component, like FadingGrid, and use as normal. However, now removeChildAt is not overridden and thus using it won’t produce the fade effect.