Question

I want to to select all the nodes for a given id but that could end in an additional number. How can I do that?

Example:

 <group id="list">
 <group id="list1">
 <group id="list2">
 <group id="map">
 <group id="map1">

---

The declaration Im having now:

<xsl:variable name="rule">
<data>
    <node>list</node>
    <node>map</node>
</data>
</xsl:variable>

<xsl:template match="/">
    <xsl:apply-templates select=".//group[ @id = exslt:node-set($rule)/data/node]"/>
</xsl:template>

and it only allows my to work on the nodes specified in the “rule” list. [XSLT v1.0]

Please advise.

Answer 1

I. XSLT 1.0 solution:

This transformation:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pIds">
  <id>list</id>
  <id>map</id>
 </xsl:param>

 <xsl:variable name="vIds" select=
  "document('')/*/xsl:param[@name='pIds']/*"/>

 <xsl:template match="group">
  <xsl:if test=
  "$vIds[. = current()/@id
        or
         starts-with(current()/@id, .)
        and
         substring-after(current()/@id, .)
        =
         floor(substring-after(current()/@id, .))
        ]
  ">
   <!-- Processing here: -->
   <xsl:copy-of select="."/>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

when applied on this XML document:

<t>
 <group id="list"/>
 <group id="list1"/>
 <group id="listX"/>
 <group id="list2"/>
 <group id="map"/>
 <group id="map123Z"/>
 <group id="map1"/>
</t>

processes (in this example copies) exactly the matching nodes:

<group id="list"/>
<group id="list1"/>
<group id="list2"/>
<group id="map"/>
<group id="map1"/>

Explanation:

1. Use of the standard XPath functions starts-with(), substring-after() and floor().

2. An easy test if a string is castable to an integer is: floor($s) = $s

II. XSLT 2.0 solution:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pIds" select="'list', 'map'"/>

 <xsl:variable name="vIds" select=
  "document('')/*/xsl:param[@name='pIds']/*"/>

 <xsl:template match=
 "group
   [@id = $pIds
   or
    $pIds
      [starts-with(current()/@id, .)
     and
        substring-after(current()/@id, .)
       castable as
        xs:integer
       ]
    ]
 ">
   <!-- Processing here: -->
   <xsl:copy-of select="."/>
 </xsl:template>
</xsl:stylesheet>

Explanation: This solution is quite similar to the XSLT 1.0 solution with the following major differences:

1. In XSLT 2.0 it is allowed to have variable/parameter references in the match pattern. Using this we avoid the <xsl:if> inside the template body.

2. We define the parameter to contain a sequence of the desired strings.

3. We use the standard XPath 2.0 operator castable as.