Question

I want to use a regular expression to check a string to make sure 4 and 5 are in order. I thought I could do this by doing

'$string =~ m/.45./'

I think I am going wrong somewhere. I am very new to Perl. I would honestly like to put it in an array and search through it and find out that way, but I’m assuming there is a much easier way to do it with regex.

print "input please:\n";
$input = <STDIN>;
chop($input);
if ($input =~ m/45/ and $input =~ m/5./) {
    print "works";
}
else {
    print "nata";
}

EDIT: Added Info
I just want 4 and 5 in order, but if 5 comes before at all say 322195458900023 is the number then where 545 is a problem 5 always have to come right after 4.

Answer 1

Assuming you want to match any string that contains two digits where the first digit is smaller than the second:

There is an obscure feature called "postponed regular expressions". We can include code inside a regular expression with

(??{CODE})

and the value of that code is interpolated into the regex.

The special verb (*FAIL) makes sure that the match fails (in fact only the current branch). We can combine this into following one-liner:

perl -ne'print /(\d)(\d)(??{$1<$2 ? "" : "(*FAIL)"})/ ? "yes\n" :"no\n"'

It prints yes when the current line contains two digits where the first digit is smaller than the second digit, and no when this is not the case.

The regex explained:

m{
   (\d)   # match a number, save it in $1
   (\d)   # match another number, save it in $2
   (??{   # start postponed regex
      $1 < $2      # if $1 is smaller than $2
      ? ""         # then return the empty string (i.e. succeed)
      : "(*FAIL)"  # else return the *FAIL verb
   })     # close postponed regex
}x;       # /x modifier so I could use spaces and comments

However, this is a bit advanced and masochistic; using an array is (1) far easier to understand, and (2) probably better anyway. But it is still possible using only regexes.

---

Edit

Here is a way to make sure that no 5 is followed by a 4:

/^(?:[^5]+|5(?=[^4]|$))*$/

This reads as: The string is composed from any number (zero or more) characters that are not a five, or a five that is followed by either a character that is not a four or the five is the end of the string.

This regex is also a possibility:

/^(?:[^45]+|45)*$/

it allows any characters in the string that are not 4 or 5, or the sequence 45. I.e., there are no single 4s or 5s allowed.