Question

I want to write string reverse function without using either append or reverse functions.

I wrote the code as follows:

> (define rdc(lambda (ls)
                   (cond((null? ls) '())
                        (else (cons (rdc (cdr ls)) (car ls))))))

The output for this code is as follows:

Input: > (rdc '(a b c))
Output: (((() . c) . b) . a)

But I want output in the form of (c b a). I’m using DrScheme

Answer 1

Your solution is performing the cons operation in the wrong order, that’s why the result is not a well-formed list.

The correct answer is simple using an accumulator for storing the answer – with the nice side effect that this is a tail-recursive solution:

(define (rdc lst)
  (let loop ((lst lst)
             (acc '()))
    (if (null? lst)
        acc
        (loop (cdr lst) (cons (car lst) acc)))))

The previous procedure uses a named let for implementing the recursion. Alternatively, you could use an inner helper procedure, this version is completely equivalent:

(define (rdc lst)
  (define (loop lst acc)
    (if (null? lst)
        acc
        (loop (cdr lst) (cons (car lst) acc))))
  (loop lst '()))

Either way, this works:

(rdc '(a b c))
> '(c b a)