Question

I wanted to ask a question about assigning distinct values in Z3.

suppose that I have 6 variables A,B,C,D,E,F.
Now, I would like to assign distinct values to some of them and some of them will be zero. How many variables will be distinct and how many variables are zero is unknown before-hand. It depends on certain other conditions.

generally for all the variables I shall write

(assert (distinct A B C D E F))

However is it possible to write constraint such as A, B, D are zero and others are distinct? Again remember that A,B, D are just example variables. They can change dynamically depending on the constraints.

Thanks !

Answer 1

As far as I understand, you have a set V of variables v₁, …, v_n, where each variable v_i is either zero or different from all other variables v_j, j ≠ i.

As an example, let V = {a, b, c, d}.

(declare-const a Int)
(declare-const b Int)
(declare-const c Int)
(declare-const d Int)

You could encode your constraints as

(assert (or (= a 0) (not (or (= a b) (= a c) (= a d)))))
(assert (or (= b 0) (not (or (= b a) (= b c) (= b d)))))
(assert (or (= c 0) (not (or (= c a) (= c b) (= c d)))))
(assert (or (= d 0) (not (or (= d a) (= d b) (= d c)))))

Adding two constraints and querying Z3 for a model

(assert (= a 0))
(assert (not (= b 0)))

(check-sat)
(get-model)

then yields

sat
(model 
  (define-fun b () Int
    (- 2))
  (define-fun c () Int
    (- 1))
  (define-fun d () Int
    0)
  (define-fun a () Int
    0)
)

Since generating the “zero or distinct” constraints is a tedious task you’d probably want to work with a Z3 front-end such as PyZ3 or Scala^Z3.