Question

I wanted to get the words from a cell. For example, cell A2 has a value of “My name is jayson”. I wanted to get the words: “name” & “jayson”. I want to exclude words with less than 3 characters. How do I do it using a formula/function in excel?

Thanks.

Answer 1

This code should be run from the sheet that contains your data to be splice. I have assumed that you are working in column A

The code

1. Uses a regular expression to remove all alphanumeric strings less or equal to 3 characters
2. Dumps a revised set of strings to a newly created sheet
3. Splits these strings using excel’s “Text to Columns”

Variant arrays are used to make this an efficient process

{Update: added no loop version}

Original Code

    Sub Spliced()
        Dim ws1 As Worksheet
        Dim ws2 As Worksheet
        Dim rng1 As Range
        Dim objRegex
        Dim X
        Dim lngRow As Long

        Set ws1 = Sheets(1)
        Set rng1 = ws1.Range(ws1.[a1], ws1.Cells(Rows.Count, "A").End(xlUp))
        Set ws2 = Sheets.Add

        X = rng1.Value2
        Set objRegex = CreateObject("vbscript.regexp")
        With objRegex
            .Pattern = "\b\w{1,3}\b"
            .Global = True
        End With

        For lngRow = 1 To UBound(X)
            X(lngRow, 1) = Application.Trim(objRegex.Replace(X(lngRow, 1), vbNullString))
        Next

        ws2.Range(rng1.Address) = X
        ws2.Columns("A").TextToColumns Destination:=Range("A1"), DataType:=xlDelimited, _
                                       TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=True, Space:=True
    End Sub

Updated:No loops

Sub Spliced_NoLoops()
    Dim ws1 As Worksheet
    Dim ws2 As Worksheet
    Dim rng1 As Range
    Dim objRegex
    Dim strDelim As String
    Dim strOut As String

    strDelim = "||"
    Set ws1 = Sheets(1)
    Set rng1 = ws1.Range(ws1.[a1], ws1.Cells(Rows.Count, "A").End(xlUp))
    strOut = Join(Application.Transpose(rng1), strDelim)

    Set ws2 = Sheets.Add
    Set objRegex = CreateObject("vbscript.regexp")
    With objRegex
        .Pattern = "\b\w{1,3}\b"
        .Global = True
    End With

    ws2.Range(rng1.Address) = Application.Transpose(Split(Application.Trim(objRegex.Replace(strOut, vbNullString)), "||"))
    ws2.Columns("A").TextToColumns Destination:=Range("A1"), DataType:=xlDelimited, _
                                   TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=True, Space:=True
End Sub