Question

I was trying out the example given at http://www.haskell.org/haskellwiki/State_Monad#Complete_and_Concrete_Example_1

How this makes the solution composible is beyond my understanding. Here is what I tried but I get compile errors as follows:

Couldn't match expected type `GameValue -> StateT GameState Data.Functor.Identity.Identity b0'
            with actual type `State GameState GameValue'
In the second argument of `(>>=)', namely `g2'
In the expression: g1 >>= g2
In an equation for `g3': g3 = g1 >>= g2
Failed, modules loaded: none.

Here is the code: See the end lines

module StateGame where
import Control.Monad.State

type GameValue = Int
type GameState = (Bool, Int)

-- suppose I want to play one game after the other
g1 = playGame "abcaaacbbcabbab"
g2 = playGame "abcaaacbbcabb"
g3 = g1 >>= g2

m2 = print $ evalState g3 startState

playGame :: String -> State GameState GameValue
playGame []     = do
    (_, score) <- get
    return score

playGame (x:xs) = do
    (on, score) <- get
    case x of
         'a' | on -> put (on, score + 1)
         'b' | on -> put (on, score - 1)
         'c'      -> put (not on, score)
         _        -> put (on, score)
    playGame xs

startState = (False, 0)

main str = print $ evalState (playGame str) startState

Answer 1

There are two ways you can combine your two games. The first option is to run the second game after the first game, starting from a fresh state. You do this using:

main = do
    print $ evalState g1 startState
    print $ evalState g2 startState

Alternatively, you can have the second game pick up where the first game ended. You do this using:

g3 = do
    g1
    g2

… which is just syntactic sugar for:

g3 = g1 >> g2

… and run it with:

main = print $ evalState g3 startState