Question

I was wondering if someone can help me solve the following problem. Someone has previously helped me on get the % of dctest/In value on the same worksheet. But right now, i need to do the same thing but on a different worksheet.

Say Sheet1

this is copied Sheet1 (1) after taking the %

Sub marco1()

'start making Sheet1 into %
'~~> Add/Remove the text here which you want to ignore
Excludetext = "In,test1,test2,test3,test4,test5,test6"

MyArray = Split(Excludetext, ",")

Set ws = Sheets("Sheet1")
LastRow = ws.Range("A" & Rows.Count).End(xlUp).Row

'Set Column B into %
For i = 1 To LastRow
    boolContinue = True

    For j = 0 To UBound(MyArray)
        SearchText = UCase(Trim(MyArray(j)))
        If UCase(Trim(ws.Range("A" & i).Value)) = SearchText Then
            boolContinue = False
            Exit For
        End If
    Next j

    If boolContinue = True Then
        With Range("B" & i)
            .Formula = _
            "=OFFSET(INDIRECT(ADDRESS(INDEX(MATCH(A" & i & _
            ",$A$1:$A$45,0),1,0),1,1,1,'Duplicated_Sheet1')),0,1)/$B$5"
            .NumberFormat = "0.00%"
        End With
    End If
Next i
End sub

There is some error showing at the formula, did i make a mistake with the formula? Thank you in advance!

Answer 1

Is this what you are trying?

TRIED AND TESTED

Option Explicit

Sub Sample()
    Dim ws As Worksheet
    Dim wsData As String
    Dim SearchText As String, Excludetext As String
    Dim LastRow As Long, i As Long, j As Long
    Dim MyArray() As String
    Dim boolContinue As Boolean

    '~~> Add/Remove the text here
    Excludetext = "In,Test1,Test2,Test3,Test4,Test5,Test6"

    '~~> Change this to the relevant sheetname which has the data
    wsData = "Sheet1"

    MyArray = Split(Excludetext, ",")

    Set ws = Sheets("Sheet2")
    LastRow = ws.Range("A" & Rows.Count).End(xlUp).Row

    For i = 1 To LastRow
        boolContinue = True

        For j = 0 To UBound(MyArray)
            SearchText = MyArray(j)
            If ws.Range("A" & i).Value = SearchText Then
                boolContinue = False
                Exit For
            End If
        Next j

        If boolContinue = True Then
            With ws.Range("B" & i)
                .Formula = _
                "=OFFSET(INDIRECT(ADDRESS(INDEX(MATCH(A" & i & _
                "," & wsData & "!$A$1:$A$11,0),1,0),1,1,TRUE,""" & _
                wsData & """)),0,1)/" & wsData & "!B1"
                .NumberFormat = "0.00%"
            End With
        End If
    Next i
End Sub

When using ADDRESS() for a cell in different sheet, you have to specify additional arguments.

Straight from Excel’s help

Syntax of ADDRESS Function

ADDRESS(row_num, column_num, [abs_num], [a1], [sheet_text])

Where [sheet_text] is the name of the sheet which we are referring to. I would recommend reading more about it in Excel Help.

This is the actual formula for say dctest

=OFFSET(INDIRECT(ADDRESS(INDEX(MATCH(A7,Sheet1!$A$1:$A$11,0),1,0),1,1,TRUE,"Sheet1")),0,1)/Sheet1!B1

HTH

Sid