Question

I woul like to access Apex_application.g_fXX values from within the database stored procedure, either by passing the whole array as an input parameter or by reading session state from within the database. Is this possible? My reason for trying to do this is that I want to move all heavy processing to the database.

TIA, Tamas

Answer 1

Sure, why wouldn’t it work?

CREATE OR REPLACE PACKAGE "APXPA_TEST" IS
   PROCEDURE process_something;
   PROCEDURE process_something2(i_values IN apex_application_global.vc_arr2);
END "APXPA_TEST";
/
CREATE OR REPLACE PACKAGE BODY "APXPA_TEST" IS   
   PROCEDURE process_something
   IS
   BEGIN
      FOR i in 1..apex_application.g_F02.COUNT
      LOOP
         apex_debug_message.log_message('processing '||apex_application.g_f02(i)||'...');
      END LOOP;
   END;

   PROCEDURE process_something2(i_values IN apex_application_global.vc_arr2)
   IS
   BEGIN
      FOR i IN 1..i_values.COUNT
      LOOP
         apex_debug_message.log_message('processing '||i_values(i)||'...');       
      END LOOP;
   END;
end "APXPA_TEST";
/

I made a page with a tabular form based on EMP. I created a page process with process point On Submit - After Computations and Validations, before the MRU.

apxpa_test.process_something;
apxpa_test.process_something2(apex_application.g_f02);

G_F02 holds ENAME

Now run the page and enable debug. Then just submit the form (you don’t need to edit anything), and go to view debug. Pick the last entry. Scroll to the point where it goes over the page processes: you’ll see the output there. (i only used deptartment 10)

Processes - point: AFTER_SUBMIT
...Process "some process" - Type: PLSQL
...Execute Statement: begin apxpa_test.process_something; apxpa_test.process_something2(apex_application.g_f02); end;
processing KING...
processing CLARK...
processing MILLER...
processing KING...
processing CLARK...
processing MILLER...
...Process "ApplyMRU" - Type: MULTI_ROW_UPDATE
...Process "ApplyMRD" - Type: MULTI_ROW_DELETE