Question

I would like to ask your help in a possibly simple situation (where the solution is yet unknown for me).

I am trying to provide a variable for the if command to make a bit more “dynamic” the code, but this fails for me with:
% was unexpected at this time.

Here is a simple example for that:

> for %i in (NEQ) do (if 1 %i 2 echo jo)
%i was unexpected at this time.

While the following works like charm:

>set oper=NEQ
>for %i in (NEQ) do (if 1 %oper% 2 echo works)
works

As I should stay in the for loop (and I get the actual operator from the for loop in the real code), I am really stuck how to solve it…

Tried to play with EnableDelayedExpansion as well, but !variable! instead of the operator is refused as well. Is there a way to submit the variable in a FOR loop for IF, without major modifications in the script?

Answer 1

Is there a way to submit the variable in a FOR loop for IF?

No!
Because, the IF statement has it’s own parser and it expects some tokens already expanded at this parse phase.
So it’s neither possible to expand the options nor the operator, nor NOT.
But it’s allowed to expand the values with delayed or FOR-variables.

setlocal EnableDelayedExpansion
set myOperator=EQU
IF 1 %myOperator% 1 echo Works
IF 1 !myOperator! 1 echo FAILS
for %%O in (EQU) do IF 1 %%O 1 echo Works

The percent expansion works, as it is expanded before the IF parser gets the line.

If you really need to use variable operators, then you need to use a function.

for %%O in (EQU) do call :myFunc %%O
exit /b

:myFunc 
IF ONE %1 ONE echo Works
exit /b

EDIT:
And the special parser is also the cause, that it’s not possible to use here a CALL expansion for the IF statement.

Like this idea

set myOperator=EQU
CALL IF 1 %%myOperator%% 1 echo Works

This should expand to IF 1 EQU 1 echo Works, but the combination of CALL and IF fails always.