Question

I would like to convert data.txt into scheme list using sed into the following format:

-Each every line with same starting number will be parsed and combined like so:

data.txt

1,{},344.233
1,{2},344.197
2,{16},290.281
2,{18},289.093
3,{1},220.896

foo.scm

(define v1 '(1 (() 344.233) ((2) 344.197))) ;; this is for first two lines starting with 1
(define v2 '(2 ((16) 290.281) ((18) 289.093))) ;; ... 2
(define v3 '(3 (() 237.558))) ;; ... 3

Answer 1

I know nothing about scheme, so I’d probably do this in awk rather than sed.

[ghoti@pc ~]$ cat data.txt 
1,{},344.233
1,{2},344.197
2,{16},290.281
2,{18},289.093
3,{1},220.896
[ghoti@pc ~]$ cat doit.awk 
#!/usr/bin/awk -f

BEGIN {
  FS=",";
  last1=1;
}

$1 != last1 {
  printf("(define v%.0f '(%.0f %s))\n", last1, last1, substr(sect,2));
  last1=$1; sect="";
}

{
  gsub(/[^0-9]/,"",$2);
  sect=sprintf("%s ((%s) %s)", sect, $2, $3);
}

END {
  printf("(define v%.0f '(%.0f %s))\n", last1, last1, substr(sect,2));
}

[ghoti@pc ~]$ ./doit.awk data.txt 
(define v1 '(1 (() 344.233) ((2) 344.197)))
(define v2 '(2 ((16) 290.281) ((18) 289.093)))
(define v3 '(3 ((1) 220.896)))
[ghoti@pc ~]$ 

It could certainly be written more tightly, but this gets the job done.

UPDATE: (per comments)

[ghoti@pc ~]$ tail -1 data.txt 
3,{1,3,4},220.896
[ghoti@pc ~]$ diff -u doit.awk doitnew.awk 
--- doit.awk    2012-05-30 00:38:34.549680376 -0400
+++ doitnew.awk 2012-05-30 00:38:52.893810815 -0400
@@ -10,8 +10,15 @@
   last1=$1; sect="";
 }

+$2 !~ /}$/ {
+  while ($2 !~ /}$/) {
+    pos=match($0, /,[0-9,]+}/);
+    $0=substr($0, 0, pos-1) " " substr($0, pos+1);
+  }
+}
+
 {
-  gsub(/[^0-9]/,"",$2);
+  gsub(/[^0-9 ]/,"",$2);
   sect=sprintf("%s ((%s) %s)", sect, $2, $3);
 }

[ghoti@pc ~]$ ./doitnew.awk data.txt 
(define v1 '(1 (() 344.233) ((2) 344.197)))
(define v2 '(2 ((16) 290.281) ((18) 289.093)))
(define v3 '(3 ((1 3 4) 220.896)))
[ghoti@pc ~]$ 

What’s going on here?

In the new block we’re adding, test to see whether the second field ends in a }. If it doesn’t, we’ll loop until it does. For each run of the loop, we’ll remove a comma before the }, replacing it with a space.

Sometimes, brute-force works. 😛