Question

I would like to extends the Event class to add some events I am using in game.
But I don’t want the new Event Class to have the old public static types..
For instance I don’t want to have:

NewEventClass.ENTER_FRAME

How do you go about extending the Event class without getting the old types mixed in?

Is there any way to outsmart AS3 to leave out the uneeded types?

Or should I avoid creating a new Event type altogether and just add the new strings?

Answer 1

Extending Event is only really necessary if you want to add some extra properties to it, for example:

public class EnemyEvent extends Event
{
    // Constants used to represent event type
    public static const ENEMY_KILLED:String = "killed";

    // Event properties
    public var score:int = 0;

    /**
     * Constructor
     * Retain Event behaviours
     */
    public function EnemyEvent(type:String, bubbles:Boolean=false, cancelable:Boolean=false)
    {
        super(type, bubbles, cancelable);
    }
}

So that when you dispatch this event from an enemy you can go:

var evt:EnemyEvent = new EnemyEvent(EnemyEvent.ENEMY_KILLED);
evt.score = myScoreValue;

dispatchEvent(evt);

And then make use of the score property from the listening method within the game engine:

enemy.addEventListener(EnemyEvent.ENEMY_KILLED, _countKill);
function _countKill(e:EnemyEvent):void
{
    gameTotalScore += e.score;
    if(gameTotalScore > 100) getAchievement();

    e.target.removeEventListener(e.type, _countKill); // <-- woudn't work without extending event either
}

If you just need to store constants to use in addEventListener(x, ..), new Event(x), etc then you can just make a class that holds these and doesn’t have anything to do with Event:

public class CustomEvents
{
    public static const MY_CUSTOM_EVENT:String = "myCustomEvent";
}

So that you can just use these as needed:

• new Event(CustomEvents.MY_CUSTOM_EVENT);
• addEventListener(CustomEvents.MY_CUSTOM_EVENT, _listener);

The former method is still preferable as it’s tidier and more logical.

Additionally; your note about your custom event having constants such as ENTER_FRAME isn’t the case anyway, because they are static and belong to Event. You’ll get this error if you try access ENTER_FRAME through the example in your answer:

1119: Access of possibly undefined property ENTER_FRAME through a
reference with static type Class.