Question

I would like to pass the noconstant option from a wrapper program to an inside regress call. The following solution works, but it seems particularly janky and not extensible if I would like to pass several options.

webuse grunfeld, clear

capture program drop regress_wrapper
program define regress_wrapper
    version 11.2
    syntax varlist(min=2 numeric) [if] [in] ///
        [, noconstant(string)]
    tokenize `varlist'
    local y `1'
    macro shift
    local x `*'
    regress `y' `x', `noconstant'
end    

regress_wrapper invest mvalue kstock
regress_wrapper invest mvalue kstock, noconstant(noconstant)

I thought that something more like the following would work, but it doesn’t pass the noconstant option.

capture program drop regress_wrapper
program define regress_wrapper
    version 11.2
    syntax varlist(min=2 numeric) [if] [in] ///
        [, noconstant]
    tokenize `varlist'
    local y `1'
    macro shift
    local x `*'
    regress `y' `x', `noconstant'
end    

regress_wrapper invest mvalue kstock
regress_wrapper invest mvalue kstock, noconstant

Answer 1

The second doesn’t work because the local macro ends up being called constant, not noconstant, as described at help syntax##optionally_off. So it should work if you replace:

   regress `y' `x', `noconstant'

by:

   regress `y' `x', `constant'

If you want to pass several options on, it’s easier to use the * syntax explained at help syntax##description_of_options :

If you also specify
*, any remaining options are collected and placed, one after the other in
`options’.

e.g.:

       syntax varlist(min=2 numeric) [if] [in] ///
            [, *]
       ...
       regress `y' `x', `options'