Question

I would like to run a external command in perl and filter some of the lines.
I don’t know how to filter the lines that go to stderr. I have the following code right now:

#!/usr/bin/env perl

use File::Spec;
#open STDERR, '>', File::Spec->devnull() or die "could not open STDERR: $!\n";

open(FILEHANDLE, '-|', 'Mycmd') or die "Cannot fork: $!\n";
open(STDERR, ">&FILEHANDLE");

while(defined(my $line = <FILEHANDLE>)) {
  chomp($line);
  if( $line =~ m/text1/ or
    $line =~ m/text2/ or
    $line =~ m/text3/
  ) {
    # do nothing
  }
  else {
    print "$line\n";
  }
}
close FILEHANDLE or die "child error: $!\n";

the line

open(STDERR, ">&FILEHANDLE");

is where I try to redirect the stderr to be able to process it with stdout but it doesn’t work.

The solution would have to work in windows.

Answer 1

A shell redirect in the argument to open can help here:

open(FILEHANDLE, 'Mycmd 2>&1 |') or die "Cannot fork: $!\n";

Now FILEHANDLE will see each line of both the standard output and the standard error from Mycmd.

To use multi-argument open and redirect output, you have to be more deliberate. Say Mycmd is

#! /usr/bin/env perl
print "standard output\n";
warn  "standard error\n";

Opening "-|" gives us the standard output only, so if we run

#! /usr/bin/env perl

use strict;
use warnings;

use 5.10.0;

my $pid = open my $fh, "-|", "Mycmd" // die "$0: fork: $!";

while (defined(my $line = <$fh>)) {
  chomp $line;
  print "got [$line]\n";
}

The output is

standard error
got [standard output]

Notice that the standard output from Mycmd passed through the driver program but not its standard error. To get both, you have to mimic the shell’s redirection.

#! /usr/bin/env perl

use strict;
use warnings;

use 5.10.0;

my $pid = open my $fh, "-|" // die "$0: fork: $!";

if ($pid == 0) {
  open STDERR, ">&STDOUT" or die "$0: dup: $!";
  exec "Mycmd"            or die "$0: exec: $!";
}

while (defined(my $line = <$fh>)) {
  chomp $line;
  print "got [$line]\n";
}

Now the output is

got [standard error]
got [standard output]