Question

I would like to run weekly reports (from Monday to Sunday) based on a timesheets table, so that I can see what type of jobs are being requested and booked.

In the timesheets table there is a start_dtm and end_dtm

How would I run a query to check for Start and End of the week?

edit: I have the following code which grabs the start and end date:

---------------------------------
--Please set your appropriate values for @REPORT_DATE and @WEEK_BEGINING
DECLARE @REPORT_DATE DATETIME, @WEEK_BEGINING VARCHAR(10)
SELECT @REPORT_DATE = '2012-03-16T00:00:00'
SELECT @WEEK_BEGINING = 'MONDAY'
IF @WEEK_BEGINING = 'MONDAY'
SET DATEFIRST 1
ELSE IF @WEEK_BEGINING = 'TUESDAY'
SET DATEFIRST 2
ELSE IF @WEEK_BEGINING = 'WEDNESDAY'
SET DATEFIRST 3
ELSE IF @WEEK_BEGINING = 'THURSDAY'
SET DATEFIRST 4
ELSE IF @WEEK_BEGINING = 'FRIDAY'
SET DATEFIRST 5
ELSE IF @WEEK_BEGINING = 'SATURDAY'
SET DATEFIRST 6
ELSE IF @WEEK_BEGINING = 'SUNDAY'
SET DATEFIRST 7
DECLARE @WEEK_START_DATE DATETIME, @WEEK_END_DATE DATETIME
--GET THE WEEK START DATE
SELECT @WEEK_START_DATE = @REPORT_DATE - (DATEPART(DW, @REPORT_DATE) - 1)
--GET THE WEEK END DATE
SELECT @WEEK_END_DATE = @REPORT_DATE + (7 - DATEPART(DW, @REPORT_DATE))
PRINT 'Week Start: ' + CONVERT(VARCHAR, @WEEK_START_DATE)
PRINT 'Week End: ' + CONVERT(VARCHAR, @WEEK_END_DATE)
----------------------------------------------

Answer 1

You can use this SQL to determine Monday and Friday of the week of a given date

SET DATEFIRST 1
DECLARE @Date date = GETDATE() --give a date here

SELECT
    @Date [SelectedDate], 
    DATENAME(dw, @Date) [SelectedWD],
    DATEADD(dd, -(DATEPART(dw, @Date)-1), @Date) [WeekStart],
    DATENAME(dw, DATEADD(dd, -(DATEPART(dw, @Date)-1), @Date)) [WeekStartWD],
    DATEADD(dd, 7-(DATEPART(dw, @Date)+2), @Date) [WeekEnd],
    DATENAME(dw, DATEADD(dd, 7-(DATEPART(dw, @Date)+2), @Date)) [WeekEndWD]

**Example output**
SelectedDate    SelectedWD  WeekStart   WeekStartWD WeekEnd     WeekEndWD
2012-03-16      Friday      2012-03-12  Monday      2012-03-16  Friday

——————————————— EDIT ———————————————
USAGE

This gives you the results for 1 week (only weekdays)

SET DATEFIRST 1
DECLARE @Date date = GETDATE() --give a date here
DECLARE @WeekStart Date, @WeekEnd Date

select @WeekStart = DATEADD(dd, -(DATEPART(dw, @Date)-1), @Date),
@WeekEnd = DATEADD(dd, 7-(DATEPART(dw, @Date)+2), @Date)

SELECT * FROM myTable WHERE myDate BETWEEN @WeekStart AND @WeekEnd