Question

I would like to transform an XML document using xslt with a set of row nodes and column nodes into an xhtml table.

The column nodes define data about the associated row attribute. For example, the first column node specifies that the ID attribute of the Row node should be hidden (i.e. not show up in the table). The Caption element of the Column node defines what the column header text should be.

I’ve seen solutions where you know the attributes that you want to turn into columns ahead of time, but I’m not sure how to use the relevant column data to format the headers

Input:

<TableData>
    <Columns>
         <Column Name="ID" Hidden="true" />
         <Column Name="Name" Caption="Item Name" />
         <Column Name="Desc" Caption="Item Description" />
    </Columns>
    <Rows>
         <Row ID="0" Name="A" />
         <Row ID="1" Name="B" Desc="Some description"/>
         <Row ID="3" Name="C" />
    </Rows>
</TableData>

Desired output would be a table in (x)html something like this:

Item Name      | Item Description
--------------------------------------
A              |      
B              | Some Description
C              |

Answer 1

This transformation:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:key name="RowAttribsByName" match="Row/@*"
      use="concat(generate-id(..), '|', name())"/>

 <xsl:variable name="vColNames" select=
  "/*/Columns/*[not(@Hidden = 'true')]/@Name"/>

 <xsl:template match="/*">
  <table border="1">
    <tr>
     <xsl:apply-templates select="Columns/*"/>
    </tr>
    <xsl:apply-templates select="Rows/Row"/>
  </table>
 </xsl:template>

 <xsl:template match="Column[not(@Hidden = 'true')]">
  <td><xsl:value-of select="@Caption"/></td>
 </xsl:template>

 <xsl:template match="Row">
  <tr>
   <xsl:apply-templates select="$vColNames">
     <xsl:with-param name="pRowId"
          select="generate-id()"/>
   </xsl:apply-templates>
  </tr>
 </xsl:template>

 <xsl:template match="Column/@*">
  <xsl:param name="pRowId"/>

  <td width="50%">
    <xsl:value-of select=
      "key('RowAttribsByName',
           concat($pRowId, '|', .)
           )
    "/>
  </td>
 </xsl:template>
</xsl:stylesheet>

when applied on the provided XML document:

<TableData>
    <Columns>
        <Column Name="ID" Hidden="true" />
        <Column Name="Name" Caption="Item Name" />
        <Column Name="Desc" Caption="Item Description" />
    </Columns>
    <Rows>
        <Row ID="0" Name="A" />
        <Row ID="1" Name="B" Desc="Some description"/>
        <Row ID="3" Name="C" />
    </Rows>
</TableData>

produces the wanted, correct result:

<table border="1">
   <tr>
      <td>Item Name</td>
      <td>Item Description</td>
   </tr>
   <tr>
      <td width="50%">A</td>
      <td width="50%"/>
   </tr>
   <tr>
      <td width="50%">B</td>
      <td width="50%">Some description</td>
   </tr>
   <tr>
      <td width="50%">C</td>
      <td width="50%"/>
   </tr>
</table>