Question

I would like to traverse a folder and all it’s subfolders, keep a counter variable of the current file and rename it to $counter$ExistingFileName.
E.g.

$count = 1;  
foreach $file in $folder  
{  
  $file.name = $count + $file.name;  
  $count++;  
}

The person who can answer this will be my hero! 🙂
Btw I am using Windows 7.

Answer 1

All right, while you are pondering over my questions in my comment to your post (or maybe still making your way back to this site to read them), here’s my trial shot:

@ECHO OFF
SET "rootdir=%~1"
IF "%rootdir%"=="" SET rootdir=.
SET cnt=0
FOR /R "%rootdir%" %%f IN (*) DO (
  SET /A cnt+=1
  SETLOCAL EnableDelayedExpansion
  RENAME "%%f" "!cnt!%%~nxf"
  ENDLOCAL
)

This will rename your files by simply prepending their names with numbers, like this:

1file.txt
2program.exe
...

If you like, you can have it this way:

00001file.txt
00002program.exe

For that you’ll need to make two changes to the above script (highlighted in bold):

@ECHO OFF
SET "rootdir=%~1"
IF "%rootdir%"=="" SET rootdir=.
SET cnt=10000
FOR /R "%rootdir%" %%f IN (*) DO (
  SET /A cnt+=1
  SETLOCAL EnableDelayedExpansion
  RENAME "%%f" "!cnt:~1!%%~nxf"
  ENDLOCAL
)