Question

I would like to use VBA to run a Google search. It is important for me to be able to put in the search word one letter at a time into the Google search bar. This is my current code:

myie.document.all("q").Value = "cheese"

This will load the search term “cheese” into the search bar in one complete interval. I would like the search to be done in a more natural human manner; with “c” being typed into the search bar then “h” and then “e”, etc…

Any help is appreciated

Answer 1

Is this what you are trying?

Option Explicit

Private Sub CommandButton1_Click()
    WebBrowser1.Navigate "Google.com"
End Sub

Private Sub CommandButton2_Click()
    Dim strtext As String
    Dim i As Long

    strtext = "cheese"

    For i = 1 To Len(strtext)
        WebBrowser1.Document.all("q").Value = WebBrowser1.Document.all("q").Value & Mid(strtext, i, 1)
        Wait 1
    Next i
End Sub

Private Sub Wait(ByVal nSec As Long)
    nSec = nSec + Timer
    While nSec > Timer
        DoEvents
    Wend
End Sub

If you are bothered with the all results showing up when you type then you can use this as well

Sub Sample()
    Dim IE As Object

    Set IE = CreateObject("InternetExplorer.Application")

    IE.Visible = True

    '~~> Choose one of the below
    IE.Navigate ("http://www.google.com/#hl=en&q=" & "Cheese") '<~~ US
    IE.Navigate ("http://www.google.co.uk/#hl=en&q=" & "Cheese") '<~~ UK
    IE.Navigate ("http://www.google.co.in/#hl=en&q=" & "Cheese") '<~~ INDIA
End Sub