Question

I wrote a code in vbscript as below ,but when i run my script it is giving an error saying the “Range” is undefined. Can any help me here by saying what is the error?

For TaskCounter = 1 to 35    
  TaskRangeFrom="Task"&TaskCounter&" Start Date"    
  TaskRangeTo="Task"&(TaskCounter+1)&" Name"    
  objSheet6.Range(Range(TaskRangeFrom).Offset(,1), _ 
  Range(TaskRangeTo).Offset(,-1)).EntireColumn.Delete
Next 

Thanks in advance.

Answer 1

As @NickSlash mentioned yesterday, I doubt that you have given range names like
“Business Process ID” (containg spaces) to your columns. But as this may be
a version thing, I show you how to get a ‘whole column’ range object for a
column named “TaskB” (via the “define name” dialog):

' Range by Name
Set oRng = oWs.Range("TaskB")

To get a range for the second column by (column) number, use:

' Range by Number
Set oRng = oWs.Cells(1, 2).EntireColumn

Please note: row and column numbers start with 1. So your “.Offset(,1)”
code looks very fishy; it may have caused the “Unknown runtime error”.

If you – as I suppose – wrote your column titles in the first row, you’ll
have to loop over the columns of that row and check the values:

' Range by Lookup
Set oRng = Nothing
For nCol = 1 To 5
    If "Title B" = oWs.Cells(1, nCol).Value Then
       Set oRng = oWs.Cells(1, nCol).EntireColumn
       Exit For
    End If
Next

If you want to experiment, insert those snippets into test code like:

Dim oFS    : Set oFS = CreateObject("Scripting.FileSystemObject")
Dim sDir   : sDir    = oFS.GetAbsolutePathname("..\xls")
Dim sFSpec : sFSpec  = oFS.BuildPath(sDir, "work.xls")
' Start clean
oFS.CopyFile oFS.BuildPath(sDir, "13763603.xls"), sFSpec

' Open .XLS
Dim oXls : Set oXls = CreateObject("Excel.Application")
Dim oWb  : Set oWb  = oXls.Workbooks.Open(sFSpec)
Dim oWs  : Set oWs  = oWb.Worksheets(1)
Dim oRng, nCol

' Range by XXX
...

oXls.Visible = True
WScript.Stdin.ReadLine
If Not oRng Is Nothing Then
   oRng.Delete
   WScript.Stdin.ReadLine
End If
oXls.Visible = False
oWb.Close False
oXls.Quit

Pics to give evidence: